net-p2p/deluge: depend on older libtorrent-rasterbar

Deluge can't find libtorrent-rasterbar 2.x and isn't compatible
with it.

(For future, >= libtorrent-rasterbar 2 is now using python-single-r1
(in ~arch, anyway) and we need to therefore use the correct dependency
string, given it doesn't have PYTHON_TARGETS_* anymore, but instead PYTHON_SINGLE_TARGET.)

Reported on the forums at: https://forums.gentoo.org/viewtopic-t-1142958.html

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 154 insertions, 5 deletions

diff --git a/net-p2p/deluge/deluge-2.0.3-r10.ebuild b/net-p2p/deluge/deluge-2.0.3-r10.ebuild
new file mode 100644
index 000000000000..be0397a7f781
--- /dev/null
+++ b/net-p2p/deluge/deluge-2.0.3-r10.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8,9} )
+DISTUTILS_SINGLE_IMPL=1
+inherit xdg distutils-r1 systemd
+
+DESCRIPTION="BitTorrent client with a client/server model"
+HOMEPAGE="https://deluge-torrent.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.deluge-torrent.org/${PN}"
+else
+	SRC_URI="http://download.deluge-torrent.org/source/2.0/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="console geoip gtk libnotify sound webinterface"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	libnotify? ( gtk )
+	sound? ( gtk )
+"
+
+# Note: if/when Deluge supports newer libtorrent-rasterbar >= 2, please
+# move the dependency *outside* of gen_cond_dep and use PYTHON_SINGLE_USEDEP
+# instead. It doesn't seem like Deluge supports >= 2 right now.
+DEPEND="
+	$(python_gen_cond_dep '
+		<net-libs/libtorrent-rasterbar-2.0.0[python,${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	')
+	dev-util/intltool
+	acct-group/deluge
+	acct-user/deluge"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+		dev-python/rencode[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		>=dev-python/twisted-17.1.0[crypt,${PYTHON_USEDEP}]
+		>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+		<net-libs/libtorrent-rasterbar-2.0.0[python,${PYTHON_USEDEP}]
+		geoip? ( dev-python/geoip-python[${PYTHON_USEDEP}] )
+		gtk? (
+			sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			gnome-base/librsvg
+			libnotify? ( x11-libs/libnotify )
+		)
+		dev-python/mako[${PYTHON_USEDEP}]
+	')"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.3-setup.py.patch"
+	"${FILESDIR}/${PN}-2.0.3-UI-status.patch"
+	"${FILESDIR}/${PN}-2.0.3-gettext.patch"
+	"${FILESDIR}/${P}-fix-pickle.patch"
+	"${FILESDIR}/${P}-log.patch"
+)
+
+python_prepare_all() {
+	local args=(
+		-e "/Compiling po file/a \\\tuptoDate = False"
+	)
+	sed -i "${args[@]}" -- 'setup.py' || die
+	args=(
+		-e 's|"new_release_check": True|"new_release_check": False|'
+		-e 's|"check_new_releases": True|"check_new_releases": False|'
+		-e 's|"show_new_releases": True|"show_new_releases": False|'
+	)
+	sed -i "${args[@]}" -- 'deluge/core/preferencesmanager.py' || die
+
+	distutils-r1_python_prepare_all
+}
+
+esetup.py() {
+	# bug 531370: deluge has its own plugin system. No need to relocate its egg info files.
+	# Override this call from the distutils-r1 eclass.
+	# This does not respect the distutils-r1 API. DONOT copy this example.
+	set -- "${PYTHON}" setup.py "$@"
+	echo "$@"
+	"$@" || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if ! use console ; then
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/console/" || die
+		rm "${ED}/usr/bin/deluge-console" || die
+		rm "${ED}/usr/share/man/man1/deluge-console.1" ||die
+	fi
+	if ! use gtk ; then
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/gtk3/" || die
+		rm -r "${ED}/usr/share/icons/" || die
+		rm "${ED}/usr/bin/deluge-gtk" || die
+		rm "${ED}/usr/share/man/man1/deluge-gtk.1" || die
+		rm "${ED}/usr/share/applications/deluge.desktop" || die
+	fi
+	if use webinterface; then
+		newinitd "${FILESDIR}/deluge-web.init-2" deluge-web
+		newconfd "${FILESDIR}/deluge-web.conf" deluge-web
+		systemd_newunit "${FILESDIR}/deluge-web.service-3" deluge-web.service
+		systemd_install_serviced "${FILESDIR}/deluge-web.service.conf"
+	else
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/web/" || die
+		rm "${ED}/usr/bin/deluge-web" || die
+		rm "${ED}/usr/share/man/man1/deluge-web.1" || die
+	fi
+	newinitd "${FILESDIR}"/deluged.init-2 deluged
+	newconfd "${FILESDIR}"/deluged.conf-2 deluged
+	systemd_newunit "${FILESDIR}"/deluged.service-2 deluged.service
+	systemd_install_serviced "${FILESDIR}"/deluged.service.conf
+
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog
+	elog "If, after upgrading, deluge doesn't work, please remove the"
+	elog "'~/.config/deluge' directory and try again, but make a backup"
+	elog "first!"
+	elog
+	elog "To start the daemon either run 'deluged' as user"
+	elog "or modify /etc/conf.d/deluged and run"
+	elog "/etc/init.d/deluged start as root"
+	elog "You can still use deluge the old way"
+	elog
+	elog "Systemd unit files for deluged and deluge-web no longer source"
+	elog "/etc/conf.d/deluge* files. Environment variable customization now"
+	elog "happens in /etc/systemd/system/deluged.service.d/00gentoo.conf"
+	elog "and /etc/systemd/system/deluge-web.service.d/00gentoo.conf"
+	elog
+	elog "For more information look at https://dev.deluge-torrent.org/wiki/Faq"
+	elog
+}
diff --git a/net-p2p/deluge/deluge-9999.ebuild b/net-p2p/deluge/deluge-9999.ebuild
index 0d7b3a317c07..af6de067f70a 100644
--- a/net-p2p/deluge/deluge-9999.ebuild
+++ b/net-p2p/deluge/deluge-9999.ebuild
@@ -5,7 +5,7 @@ EAPI="7"
 
 PYTHON_COMPAT=( python3_{8,9} )
 DISTUTILS_SINGLE_IMPL=1
-inherit xdg distutils-r1 systemd
+inherit distutils-r1 systemd
 
 DESCRIPTION="BitTorrent client with a client/server model"
 HOMEPAGE="https://deluge-torrent.org/"
@@ -27,9 +27,12 @@ REQUIRED_USE="
 	sound? ( gtk )
 "
 
+# Note: if/when Deluge supports newer libtorrent-rasterbar >= 2, please
+# move the dependency *outside* of gen_cond_dep and use PYTHON_SINGLE_USEDEP
+# instead. It doesn't seem like Deluge supports >= 2 right now.
 DEPEND="
 	$(python_gen_cond_dep '
-		net-libs/libtorrent-rasterbar[python,${PYTHON_USEDEP}]
+		<net-libs/libtorrent-rasterbar-2.0.0[python,${PYTHON_USEDEP}]
 		dev-python/wheel[${PYTHON_USEDEP}]
 	')
 	dev-util/intltool
@@ -47,6 +50,7 @@ RDEPEND="
 		dev-python/six[${PYTHON_USEDEP}]
 		>=dev-python/twisted-17.1.0[crypt,${PYTHON_USEDEP}]
 		>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+		<net-libs/libtorrent-rasterbar-2.0.0[python,${PYTHON_USEDEP}]
 		geoip? ( dev-python/geoip-python[${PYTHON_USEDEP}] )
 		gtk? (
 			sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
@@ -54,7 +58,6 @@ RDEPEND="
 			gnome-base/librsvg
 			libnotify? ( x11-libs/libnotify )
 		)
-		net-libs/libtorrent-rasterbar[python,${PYTHON_USEDEP}]
 		dev-python/mako[${PYTHON_USEDEP}]
 	')"
 
@@ -123,8 +126,6 @@ python_install_all() {
 }
 
 pkg_postinst() {
-	xdg_pkg_postinst
-
 	elog
 	elog "If, after upgrading, deluge doesn't work, please remove the"
 	elog "'~/.config/deluge' directory and try again, but make a backup"