net-wireless/aircrack-ng: bump

new dep on hwloc

Signed-off-by: Rick Farina <zerochaos@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

3 files changed, 119 insertions, 1 deletions

diff --git a/net-wireless/aircrack-ng/Manifest b/net-wireless/aircrack-ng/Manifest
index 6a1a0a19e094..e1bd8bcece29 100644
--- a/net-wireless/aircrack-ng/Manifest
+++ b/net-wireless/aircrack-ng/Manifest
@@ -1,2 +1,3 @@
 DIST aircrack-ng-1.2-rc1.tar.gz 2046476 BLAKE2B aec848a3dedae564cc29fc94475d0dec9cfb33af5185a4bceb9f88c1a3cce7a910439405fd76390ca352e52393b9094e570bf54980af27a50709a36ffab33752 SHA512 897427c535846c0ede58b2f99ed469bc01f50f9b38fc70d5711261fca7342339192cc0c71a724fc04c99114db7534d825a44f09e7bc5754286ec44933a33e40d
 DIST aircrack-ng-1.3.tar.gz 4501507 BLAKE2B ae73303fbc0c632faa2468d5fbf0daa318767633bf92571cc53fd79d8df518c1fc03ad83397e12585a804f0171e3fe3865c070ccdb39cb43ae46edbfc880b37e SHA512 0c2376ac702cd36021b9017b40c5af9466c5689832a0e40debcb8c0a2cd13ec942170930903c4e2e06678c429a89cd4d78ab43e925b707f816bf48d6c9514ec9
+DIST aircrack-ng-1.4.tar.gz 7138756 BLAKE2B 35a499877671be99271116eb4c5a26c7c803485e46d5e8e429b5beafe900455e88d52350107f96f5fb1f46643120a1ad63c96ab45672efdcbd23bdcc54aeedf4 SHA512 cad82b6fcd64c094d427a985cd1f5bc95434f83db1811e2c8798932983759e0846cf66034e444ba8ec861547d3107560e0f1430ec03e3d3a080c5fb1207a2a09
diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.4.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.4.ebuild
new file mode 100644
index 000000000000..131e6f9c4ac2
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.4.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs distutils-r1 flag-o-matic autotools
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/aircrack-ng/aircrack-ng.git"
+	KEYWORDS="amd64 x86"
+else
+	MY_PV=${PV/_/-}
+	SRC_URI="https://download.aircrack-ng.org/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD libressl +netlink +pcre +sqlite +experimental"
+
+DEPEND="net-libs/libpcap
+	sys-apps/hwloc
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	netlink? ( dev-libs/libnl:3 )
+	pcre? ( dev-libs/libpcre )
+	airdrop-ng? ( ${PYTHON_DEPS} )
+	airgraph-ng? ( ${PYTHON_DEPS} )
+	experimental? ( sys-libs/zlib )
+	sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}"
+PDEPEND="kernel_linux? (
+		net-wireless/iw
+		net-wireless/wireless-tools
+		sys-apps/ethtool
+		sys-apps/usbutils
+		sys-apps/pciutils )
+	sys-apps/hwids
+	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="
+	airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+	airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-asan \
+		--enable-shared \
+		--disable-static \
+		--without-opt \
+		$(use_enable netlink libnl) \
+		$(use_with experimental) \
+		$(use_with sqlite sqlite3)
+}
+
+src_compile() {
+	if [[ $($(tc-getCC) --version) == clang* ]] ; then
+		#https://bugs.gentoo.org/show_bug.cgi?id=472890
+		filter-flags -frecord-gcc-switches
+	fi
+
+	default
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_compile
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	default
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_install
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_install
+	fi
+
+	# we don't need aircrack-ng's oui updater, we have our own
+	rm "${ED}"/usr/sbin/airodump-ng-oui-update
+}
+
+pkg_postinst() {
+	# Message is (c) FreeBSD
+	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+	if use kernel_FreeBSD ; then
+		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+		einfo "mode of your wireless card.  So do not care about what the manpages say about"
+		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+		echo
+		einfo "To return from monitor mode, issue the following command:"
+		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+		einfo
+		einfo "For aireplay-ng you need FreeBSD >= 7.0."
+	fi
+}
diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index 9c0c449c9577..f5006d8091e0 100644
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -27,6 +27,7 @@ SLOT="0"
 IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD libressl +netlink +pcre +sqlite +experimental"
 
 DEPEND="net-libs/libpcap
+	sys-apps/hwloc
 	!libressl? ( dev-libs/openssl:0= )
 	libressl? ( dev-libs/libressl:0= )
 	netlink? ( dev-libs/libnl:3 )