sci-astronomy/celestia: New snapshot

Closes: https://bugs.gentoo.org/716532
Closes: https://bugs.gentoo.org/741070
Closes: https://bugs.gentoo.org/797577
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/sci-astronomy/celestia/Manifest b/sci-astronomy/celestia/Manifest
index 1bc9d5465e61..4fb39b213d3e 100644
--- a/sci-astronomy/celestia/Manifest
+++ b/sci-astronomy/celestia/Manifest
@@ -1 +1,3 @@
 DIST celestia-1.7.0_pre20200316.tar.gz 69459012 BLAKE2B 8e718e8a4aa064b9be0bd5f0f1c034f3ffec42671c6eae503216f5ea2787e8c5da3315e3cb39e94e2a0eab5f067e189fe70dc9d04bff4127e9e39fba3a7117ae SHA512 db4213e1d76699ff01390f12e3763596dfd2641389743c27221b4e7934be9daca7a884dd389135894d225e8613830468ebede5664543e27e44e21e19d22d1e7f
+DIST celestia-1.7.0_pre20220120-data.tar.gz 310327016 BLAKE2B 507a8d5fd1307fc711b9604e00a1596bc971dbb2c936554ffd1f0e842bec6dc6d2233c04911dcd5a6e1405d9e5806c87ec22ba4f26f0e3d770bd1b6735777b0b SHA512 6443127b42586e4ad16b25fa39193a165065682cd8163b241bdcbbe755c2104e4c29b291898076437c4387cd72cdb3bd347a010738505f39ccb658300aff836d
+DIST celestia-1.7.0_pre20220120.tar.gz 5157089 BLAKE2B 5ce0413a58b2f4ca9ac9c585bfe1da9aaf0a0405d7e910b3f639d3b3a0532110dd5d28a0aec1c245a4bcebd549847023c2d84e8c29892e228dd87392bebd9ae3 SHA512 175e2280b334c4a2b6be9fa05a06abf8daa9e890cd03c11d359d26b7f0175b1662e3bf0d8abea04ad2f541780ac8b3898e47bc2bdc9e90e408e4607e2ae3fb29
diff --git a/sci-astronomy/celestia/celestia-1.7.0_pre20220120.ebuild b/sci-astronomy/celestia/celestia-1.7.0_pre20220120.ebuild
new file mode 100644
index 000000000000..49a7ab37c8da
--- /dev/null
+++ b/sci-astronomy/celestia/celestia-1.7.0_pre20220120.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CMAKE_IN_SOURCE_BUILD="yes"
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit desktop flag-o-matic lua-single xdg cmake
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/CelestiaProject/Celestia.git"
+	inherit git-r3
+else
+	if [[ ${PV} == *_p* ]] ; then
+		COMMIT_ID="f969b37c3ee783ed51bf4d1cbeefca4132031316"
+		COMMIT_ID_DATA="cc0bc0bb4b77e47115a31fbeb42babb30da3b790"
+		SRC_URI="
+			https://github.com/${PN^}Project/${PN^}/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz
+			https://github.com/${PN^}Project/${PN^}Content/archive/${COMMIT_ID_DATA}.tar.gz -> ${P}-data.tar.gz
+		"
+		S="${WORKDIR}/${PN^}-${COMMIT_ID}"
+		KEYWORDS="~amd64 ~x86"
+	else
+		SRC_URI="https://github.com/${PN^}Project/${PN^}/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+	fi
+fi
+
+DESCRIPTION="OpenGL 3D space simulator"
+HOMEPAGE="https://celestia.space"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ffmpeg glut lua nls +qt5"
+REQUIRED_USE="|| ( glut qt5 )
+	lua? ( ${LUA_REQUIRED_USE} )"
+
+BDEPEND="
+	dev-cpp/eigen
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+DEPEND="
+	dev-libs/libfmt:=
+	media-libs/glew:0=
+	media-libs/libpng:0=
+	sys-libs/zlib:=
+	virtual/glu
+	virtual/jpeg:0
+	virtual/opengl
+	ffmpeg? ( media-video/ffmpeg:0 )
+	glut? ( media-libs/freeglut )
+	lua? ( ${LUA_DEPS} )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	# add a ~/.celestia for extra directories
+	"${FILESDIR}"/${PN}-1.6.99-cfg.patch
+	# allow forcing CMake to look for a specific Lua version instead of the newest branch installed
+	"${FILESDIR}"/${PN}-1.7.0-cmake_lua_version.patch
+)
+
+src_prepare() {
+	mv "${WORKDIR}"/CelestiaContent-${COMMIT_ID_DATA} content || die
+
+	cmake_src_prepare
+	### This version of Celestia has a bug in the font rendering and
+	### requires -fsigned-char. We should be able to force this flag
+	### on all architectures. See bug #316573.
+	# FIXME: Point to upstream bug report if still valid
+	#append-flags "-fsigned-char"
+}
+
+src_configure() {
+	CMAKE_USE_DIR="${CMAKE_USE_DIR}/content" BUILD_DIR="${BUILD_DIR}/content" \
+		cmake_src_configure
+
+	local mycmakeargs=(
+		-DENABLE_CELX="$(usex lua)"
+		-DENABLE_NLS="$(usex nls)"
+		-DENABLE_FFMPEG="$(usex ffmpeg)"
+		-DENABLE_GLUT="$(usex glut)"
+		-DENABLE_GTK=OFF
+		-DENABLE_QT="$(usex qt5)"
+		-DENABLE_WIN=OFF
+		-DENABLE_SDL=OFF
+	)
+	# Upstream always looks for LuaJIT first unless stopped, and we only need
+	# the version specification when linking against PUC Lua
+	if use lua && ! use lua_single_target_luajit; then
+		mycmakeargs+=(
+			-DCMAKE_DISABLE_FIND_PACKAGE_LuaJIT=ON
+			-DLUA_VERSION=$(lua_get_version)
+		)
+	fi
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	CMAKE_USE_DIR="${CMAKE_USE_DIR}/content" BUILD_DIR="${BUILD_DIR}/content" cmake_src_compile
+}
+
+src_install() {
+	cmake_src_install
+
+	doicon -s 48 "${S}"/src/celestia/gtk/data/${PN}.png
+	newicon -s 128 "${S}"/src/celestia/gtk/data/${PN}-logo.png ${PN}.png
+	doicon -s scalable "${S}"/src/celestia/gtk/data/${PN}.svg
+
+	use glut && domenu "${S}"/debian/${PN}-glut.desktop
+	use qt5 && domenu "${S}"/debian//${PN}-qt.desktop
+
+	dodoc AUTHORS README TRANSLATORS *.txt
+
+	CMAKE_USE_DIR="${CMAKE_USE_DIR}/content" BUILD_DIR="${BUILD_DIR}/content" cmake_src_install
+}