sci-electronics/klayout: Version bump

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

3 files changed, 100 insertions, 3 deletions

diff --git a/sci-electronics/klayout/Manifest b/sci-electronics/klayout/Manifest
index bcd2e01bdfaa..6505c62db0f0 100644
--- a/sci-electronics/klayout/Manifest
+++ b/sci-electronics/klayout/Manifest
@@ -1 +1,2 @@
 DIST klayout-0.25.6.tar.gz 21008915 BLAKE2B f5e06790b8eac682b61bf83dce167c4c9eb8767d6bfb040e203ed2ec43b39781e64203c8319bf58ed2f4b7b2349d958f24a7ad1957bc27befa583b00eeee650c SHA512 38d13bd6f0cef5685ef32ebf00edf07f588d445174e2a56320940a7036e65a3fbb11d1efab92af9f8abfce7e77c782df5f05460a7de4d98ade924c761396db5a
+DIST klayout-0.26.4.tar.gz 52324714 BLAKE2B 663ab737d91a83452234f128b13f73ed8e559e6f0fb11f283bce6bfe80e8f391c7bac5ad16933b2f5bcf46fac6e07233ffc690dea5ddb1702850c52501157c36 SHA512 df91434e87d8cc6f4df837eacd756566626405fb75b0cce40c25f157d547dc1e5929746b6b276a317512c038e014bbdd1655615c93d76d9ed5bcf65280d95355
diff --git a/sci-electronics/klayout/klayout-0.26.4.ebuild b/sci-electronics/klayout/klayout-0.26.4.ebuild
new file mode 100644
index 000000000000..e98e242fe19b
--- /dev/null
+++ b/sci-electronics/klayout/klayout-0.26.4.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+RUBY_OPTIONAL=no
+USE_RUBY="ruby25"
+# note: define maximally ONE implementation here
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit toolchain-funcs python-single-r1 ruby-ng
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/klayoutmatthias/${PN}.git"
+	inherit git-r3
+	EGIT_CHECKOUT_DIR=${WORKDIR}/all/${P}
+else
+	SRC_URI="https://www.klayout.org/downloads/source/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
+HOMEPAGE="https://www.klayout.de/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	sys-libs/zlib
+	${PYTHON_DEPS}
+	$(ruby_implementations_depend)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ruby-ng_pkg_setup
+}
+
+each_ruby_configure() {
+	tc-export CC CXX AR LD RANLIB
+	export CFLAGS CXXFLAGS
+	./build.sh \
+		-expert \
+		-dry-run \
+		-qmake "/usr/$(get_libdir)/qt5/bin/qmake" \
+		-ruby "${RUBY}" \
+		-python "${PYTHON}" \
+		-build . \
+		-bin "${T}/bin" \
+		-rpath "/usr/$(get_libdir)/klayout" \
+		-option "${MAKEOPTS}" \
+		-with-qtbinding \
+		-without-64bit-coord \
+		-qt5 || die "Configuration failed"
+}
+
+each_ruby_compile() {
+	emake all
+}
+
+each_ruby_install() {
+	emake install
+
+	cd "${T}/bin" || die
+
+	dodir "/usr/$(get_libdir)/klayout"
+	mv lib* lay_plugins db_plugins "${ED}/usr/$(get_libdir)/klayout/" || die
+
+	dodir "$(python_get_sitedir)"
+	mv pymod/* "${ED}/$(python_get_sitedir)/" || die
+	rmdir pymod || die
+
+	dobin *
+
+	python_optimize
+}
diff --git a/sci-electronics/klayout/klayout-9999.ebuild b/sci-electronics/klayout/klayout-9999.ebuild
index 127d36ffb70f..e98e242fe19b 100644
--- a/sci-electronics/klayout/klayout-9999.ebuild
+++ b/sci-electronics/klayout/klayout-9999.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 RUBY_OPTIONAL=no
 USE_RUBY="ruby25"
 # note: define maximally ONE implementation here
 
-PYTHON_COMPAT=( python3_6 )
+PYTHON_COMPAT=( python3_{6,7,8} )
 
 inherit toolchain-funcs python-single-r1 ruby-ng
 
@@ -78,7 +78,13 @@ each_ruby_install() {
 	cd "${T}/bin" || die
 
 	dodir "/usr/$(get_libdir)/klayout"
-	mv lib* "${ED}/usr/$(get_libdir)/klayout/" || die
+	mv lib* lay_plugins db_plugins "${ED}/usr/$(get_libdir)/klayout/" || die
+
+	dodir "$(python_get_sitedir)"
+	mv pymod/* "${ED}/$(python_get_sitedir)/" || die
+	rmdir pymod || die
 
 	dobin *
+
+	python_optimize
 }