sci-libs/pcl: bump to 1.11.0

Fixes build with boost 1.73 as a side effect.
Closes: https://bugs.gentoo.org/722732
Package-Manager: Portage-2.3.99, Repoman-2.3.22

Signed-off-by: Alexis Ballier <aballier@gentoo.org>

3 files changed, 91 insertions, 6 deletions

diff --git a/sci-libs/pcl/Manifest b/sci-libs/pcl/Manifest
index 4f0161e50aca..625b774d66ea 100644
--- a/sci-libs/pcl/Manifest
+++ b/sci-libs/pcl/Manifest
@@ -1 +1,2 @@
+DIST pcl-1.11.0.tar.gz 67091890 BLAKE2B 77dcaf99e19cd3042a01176e57441a38e7f5095d7bd9b08c9ad4464384eb6c603eab9734a6bcbb52eff9da55c3aaa69b3744a10137b8264e5729c2432a678f71 SHA512 1cde48349b2630d1bb89fa50b2844054802fe02d22c810516bc41a712823a26cd5fa1b14297718f517b88c371a637567b31fb8c4c9b4908e94fb3a7208095127
 DIST pcl-1.9.1.tar.gz 67158067 BLAKE2B 472422930e08feba11f42a2df49d68e0c55484744e0649164b113dc3b654188e598b1c0a55f1b75680150090749b00378ae0f70b35b1695a7914a16be7415bf7 SHA512 ca95028c23861ac2df0fa7e18fdd0202255cb2e49ab714325eb36c35289442c6eedbf489e6f9f232b30fa2a93eff4c9619f8a14d3fdfe58f353a4a6e26206bdf
diff --git a/sci-libs/pcl/pcl-1.11.0.ebuild b/sci-libs/pcl/pcl-1.11.0.ebuild
new file mode 100644
index 000000000000..340870c8b8e2
--- /dev/null
+++ b/sci-libs/pcl/pcl-1.11.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/PointCloudLibrary/pcl"
+fi
+
+inherit ${SCM} cmake-utils multilib
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~arm"
+	SRC_URI="https://github.com/PointCloudLibrary/pcl/archive/${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${P}"
+fi
+
+HOMEPAGE="http://pointclouds.org/"
+DESCRIPTION="2D/3D image and point cloud processing"
+LICENSE="BSD"
+SLOT="0/1.11"
+IUSE="cuda doc opengl openni openni2 pcap png +qhull qt5 usb vtk cpu_flags_x86_sse test tutorials"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sci-libs/flann-1.7.1
+	dev-libs/boost:=[threads]
+	dev-cpp/eigen:3
+	opengl? ( virtual/opengl media-libs/freeglut )
+	openni? ( dev-libs/OpenNI )
+	openni2? ( dev-libs/OpenNI2 )
+	pcap? ( net-libs/libpcap )
+	png? ( media-libs/libpng:0= )
+	qhull? ( media-libs/qhull )
+	qt5? (
+		dev-qt/qtgui:5
+		dev-qt/qtcore:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtopengl:5
+	)
+	usb? ( virtual/libusb:1 )
+	vtk? ( >=sci-libs/vtk-5.6:=[imaging,rendering] )
+	cuda? ( >=dev-util/nvidia-cuda-toolkit-4 )
+"
+DEPEND="${RDEPEND}
+	!!dev-cpp/metslib
+	test? ( >=dev-cpp/gtest-1.6.0 )
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	tutorials? ( dev-python/sphinx dev-python/sphinxcontrib-doxylink )
+	virtual/pkgconfig"
+
+REQUIRED_USE="
+	openni? ( usb )
+	openni2? ( usb )
+	tutorials? ( doc )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLIB_INSTALL_DIR=$(get_libdir)"
+		"-DWITH_CUDA=$(usex cuda TRUE FALSE)"
+		"-DWITH_LIBUSB=$(usex usb TRUE FALSE)"
+		"-DWITH_OPENGL=$(usex opengl TRUE FALSE)"
+		"-DWITH_PNG=$(usex png TRUE FALSE)"
+		"-DWITH_QHULL=$(usex qhull TRUE FALSE)"
+		"-DWITH_QT=$(usex qt5 TRUE FALSE)"
+		"-DWITH_VTK=$(usex vtk TRUE FALSE)"
+		"-DWITH_PCAP=$(usex pcap TRUE FALSE)"
+		"-DWITH_OPENNI=$(usex openni TRUE FALSE)"
+		"-DWITH_OPENNI2=$(usex openni2 TRUE FALSE)"
+		"-DPCL_ENABLE_SSE=$(usex cpu_flags_x86_sse TRUE FALSE)"
+		"-DWITH_DOCS=$(usex doc TRUE FALSE)"
+		"-DWITH_TUTORIALS=$(usex tutorials TRUE FALSE)"
+		"-DBUILD_TESTS=$(usex test TRUE FALSE)"
+	)
+	cmake-utils_src_configure
+}
diff --git a/sci-libs/pcl/pcl-9999.ebuild b/sci-libs/pcl/pcl-9999.ebuild
index 19c912a12d8c..340870c8b8e2 100644
--- a/sci-libs/pcl/pcl-9999.ebuild
+++ b/sci-libs/pcl/pcl-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
 SCM=""
 if [ "${PV#9999}" != "${PV}" ] ; then
@@ -23,7 +23,7 @@ fi
 HOMEPAGE="http://pointclouds.org/"
 DESCRIPTION="2D/3D image and point cloud processing"
 LICENSE="BSD"
-SLOT="0/1.9"
+SLOT="0/1.11"
 IUSE="cuda doc opengl openni openni2 pcap png +qhull qt5 usb vtk cpu_flags_x86_sse test tutorials"
 RESTRICT="!test? ( test )"
 
@@ -49,9 +49,11 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	!!dev-cpp/metslib
+	test? ( >=dev-cpp/gtest-1.6.0 )
+"
+BDEPEND="
 	doc? ( app-doc/doxygen )
 	tutorials? ( dev-python/sphinx dev-python/sphinxcontrib-doxylink )
-	test? ( >=dev-cpp/gtest-1.6.0 )
 	virtual/pkgconfig"
 
 REQUIRED_USE="
@@ -72,9 +74,7 @@ src_configure() {
 		"-DWITH_VTK=$(usex vtk TRUE FALSE)"
 		"-DWITH_PCAP=$(usex pcap TRUE FALSE)"
 		"-DWITH_OPENNI=$(usex openni TRUE FALSE)"
-		"-DBUILD_OPENNI=$(usex openni TRUE FALSE)"
 		"-DWITH_OPENNI2=$(usex openni2 TRUE FALSE)"
-		"-DBUILD_OPENNI2=$(usex openni2 TRUE FALSE)"
 		"-DPCL_ENABLE_SSE=$(usex cpu_flags_x86_sse TRUE FALSE)"
 		"-DWITH_DOCS=$(usex doc TRUE FALSE)"
 		"-DWITH_TUTORIALS=$(usex tutorials TRUE FALSE)"