sys-cluster/neutron: bup

Package-Manager: portage-2.2.28

3 files changed, 308 insertions, 3 deletions

diff --git a/sys-cluster/neutron/Manifest b/sys-cluster/neutron/Manifest
index 0e7779e88add..84ba94a5bc0d 100644
--- a/sys-cluster/neutron/Manifest
+++ b/sys-cluster/neutron/Manifest
@@ -1,9 +1,10 @@
 DIST neutron-7.0.4.tar.gz 2535795 SHA256 6088bd85ffbf170d2463948de64b8eb8e0a5f42dcd1fdddb5283c6c5c91a5ee4 SHA512 2756681c0795b3ba0514c938c89d6b15f42c2a405371e99d547b4ed1b7bda383ae989a2d539950f782265badcce5e755f2cea9002e5875d263f1dfd8497c8d64 WHIRLPOOL 707d7c19c69a94788b45f6187cd0a3527cd67a3edacec4dea423b07f6a48cd98fdc77855d6edf2c126ce4c792f1ee8b70098aaca8c04db1fe0c332f4c8f46d04
+DIST neutron-7.1.0.tar.gz 2560006 SHA256 301f96ab109d32a0021e2d1929d0f7e9f0ddbfd915cb764596554e8bfa180afe SHA512 c58994e7d75b83d000141dd5eccbd31561f65e21656b5c1b11f27459fc5e6260b30366a70922ac3297de12aa42e88afe20fe4efff628f6b192af35d6efe1e35c WHIRLPOOL 43fbf0809a6868fe76dcdaf3ce9ffe7466f3b4701f6842b196d6dba43369f072d07d334eb1cbfadbd729d33d8822c9da6aaa42912fe9978d78bffed6b9c84987
 DIST neutron-8.0.0.tar.gz 2842712 SHA256 c6b03f33ec7f3bb325914d79c290e086e3f9d884a30962d6e2d56d6c49296a22 SHA512 ef25b2401d5dd070a2cc69370c682de36ca3b729dcd2170130530a240f936486f5bec631a45e9e7203529c1b6a91ed05b5fc4aae78d7cb2e46fc208d4a21c5a8 WHIRLPOOL 4bf710708190db86d1a91346e276118f589fdf64fe615fbccdfd979caadd3080a944ec095fad3e831e3d1021eb1b79151a07f6ab1a68c339bed399c20a287d34
-DIST neutron-8.1.0.tar.gz 2855010 SHA256 ec912b42a9058916ef65b35bf4c82aa934c181b8b3397ecfacb533b93720d362 SHA512 1bd622d9bb96241712140a0208596bc44f76d7b50c8010076125699a9857d50c34c9a37d03062b0b4db36f1859eb5368320a7564e73a8e293a6a30c44f4c3321 WHIRLPOOL d8cc0444a00326217b0194a979523a80f7761db7e8d7490cda475837ce8170d1682c850d2fec95a2ee129c4e53bcb5b6103bbc8cf36ff69b00969290d2dba8af
+DIST neutron-8.1.1.tar.gz 2821087 SHA256 f143f3cdb5527b6c152d200d3c521fcc71506cd82f88f997def754325d541572 SHA512 83724e7d943fd21e27646c0bbebf3549d0ca1431d4da6ddb202c194dbbd9dab0b06a61a97d196bb7a85407c1e6eb1b62deaa302852218cce0f705707c388f901 WHIRLPOOL 4d45c2b74f792387486c66e25abf89975089ac6c5c74d3be80656fcccdeaa0eec1203b5e1a14a8c338aa70fac57d168468871ce0dfbd886dbd72f527e772debf
 DIST neutron-configs-2016.1.9999.tar.gz 11523 SHA256 906229c66882eb05d782a749b53b9368df28ae69eb99179cbaed2640996dd227 SHA512 95ff31ce599977b8bbd7f8783ba41c1f760a30721e8a6ea84fc8f0ecfc4f429d624dad29728d5bc026f7d76a4da6e19c0f4718fd1b58b65c50ff0470a3cf8f2d WHIRLPOOL 38868696cb444cd7c4eaaf704bfb8e2efb6486aa67a99951afd43de1a8e8ca7224e8b8592a2c28e09a7a43c1a9cf0ca02e44e05a50cc370bb9dacee873022a6d
 DIST neutron-configs-8.0.0.tar.gz 11523 SHA256 906229c66882eb05d782a749b53b9368df28ae69eb99179cbaed2640996dd227 SHA512 95ff31ce599977b8bbd7f8783ba41c1f760a30721e8a6ea84fc8f0ecfc4f429d624dad29728d5bc026f7d76a4da6e19c0f4718fd1b58b65c50ff0470a3cf8f2d WHIRLPOOL 38868696cb444cd7c4eaaf704bfb8e2efb6486aa67a99951afd43de1a8e8ca7224e8b8592a2c28e09a7a43c1a9cf0ca02e44e05a50cc370bb9dacee873022a6d
-DIST neutron-configs-8.1.0.tar.gz 11523 SHA256 906229c66882eb05d782a749b53b9368df28ae69eb99179cbaed2640996dd227 SHA512 95ff31ce599977b8bbd7f8783ba41c1f760a30721e8a6ea84fc8f0ecfc4f429d624dad29728d5bc026f7d76a4da6e19c0f4718fd1b58b65c50ff0470a3cf8f2d WHIRLPOOL 38868696cb444cd7c4eaaf704bfb8e2efb6486aa67a99951afd43de1a8e8ca7224e8b8592a2c28e09a7a43c1a9cf0ca02e44e05a50cc370bb9dacee873022a6d
+DIST neutron-configs-8.1.1.tar.gz 11523 SHA256 906229c66882eb05d782a749b53b9368df28ae69eb99179cbaed2640996dd227 SHA512 95ff31ce599977b8bbd7f8783ba41c1f760a30721e8a6ea84fc8f0ecfc4f429d624dad29728d5bc026f7d76a4da6e19c0f4718fd1b58b65c50ff0470a3cf8f2d WHIRLPOOL 38868696cb444cd7c4eaaf704bfb8e2efb6486aa67a99951afd43de1a8e8ca7224e8b8592a2c28e09a7a43c1a9cf0ca02e44e05a50cc370bb9dacee873022a6d
 DIST neutron-ml2-plugins-2016.1.9999.tar.gz 2031 SHA256 af1f0436924a64d9a07f0770f06d0a2e48457b45389e1ab90e42c7157797557b SHA512 b0c194ad29d7e7a44c04b74a109523044cf268ebd8cb91965759a5cbba7cef47c252f7d0ab49bf888a74b1776891b99402dd54d45fd6099734fa03afd519350d WHIRLPOOL c279518f1868c54409a28dea03f32aa60a413af9dc3ce4387034aaab6387f1c96a937c370bcab3e6e96474a12f19f3794e7b3e0482cb067fb2b060ad09faabad
 DIST neutron-ml2-plugins-8.0.0.tar.gz 2031 SHA256 af1f0436924a64d9a07f0770f06d0a2e48457b45389e1ab90e42c7157797557b SHA512 b0c194ad29d7e7a44c04b74a109523044cf268ebd8cb91965759a5cbba7cef47c252f7d0ab49bf888a74b1776891b99402dd54d45fd6099734fa03afd519350d WHIRLPOOL c279518f1868c54409a28dea03f32aa60a413af9dc3ce4387034aaab6387f1c96a937c370bcab3e6e96474a12f19f3794e7b3e0482cb067fb2b060ad09faabad
-DIST neutron-ml2-plugins-8.1.0.tar.gz 2031 SHA256 af1f0436924a64d9a07f0770f06d0a2e48457b45389e1ab90e42c7157797557b SHA512 b0c194ad29d7e7a44c04b74a109523044cf268ebd8cb91965759a5cbba7cef47c252f7d0ab49bf888a74b1776891b99402dd54d45fd6099734fa03afd519350d WHIRLPOOL c279518f1868c54409a28dea03f32aa60a413af9dc3ce4387034aaab6387f1c96a937c370bcab3e6e96474a12f19f3794e7b3e0482cb067fb2b060ad09faabad
+DIST neutron-ml2-plugins-8.1.1.tar.gz 2031 SHA256 af1f0436924a64d9a07f0770f06d0a2e48457b45389e1ab90e42c7157797557b SHA512 b0c194ad29d7e7a44c04b74a109523044cf268ebd8cb91965759a5cbba7cef47c252f7d0ab49bf888a74b1776891b99402dd54d45fd6099734fa03afd519350d WHIRLPOOL c279518f1868c54409a28dea03f32aa60a413af9dc3ce4387034aaab6387f1c96a937c370bcab3e6e96474a12f19f3794e7b3e0482cb067fb2b060ad09faabad
diff --git a/sys-cluster/neutron/neutron-7.1.0.ebuild b/sys-cluster/neutron/neutron-7.1.0.ebuild
new file mode 100644
index 000000000000..b68506b39e5a
--- /dev/null
+++ b/sys-cluster/neutron/neutron-7.1.0.ebuild
@@ -0,0 +1,304 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 linux-info user
+
+DESCRIPTION="A virtual network service for Openstack"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="compute-only dhcp doc ipv6 l3 metadata openvswitch linuxbridge server test sqlite mysql postgres"
+REQUIRED_USE="!compute-only? ( || ( mysql postgres sqlite ) )
+						compute-only? ( !mysql !postgres !sqlite !dhcp !l3 !metadata !server
+						|| ( openvswitch linuxbridge ) )"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo
+	test? (
+		${RDEPEND}
+		>=dev-python/cliff-1.14.0[${PYTHON_USEDEP}]
+		<=dev-python/cliff-1.15.0[${PYTHON_USEDEP}]
+		>=dev-python/cliff-1.14.0[${PYTHON_USEDEP}]
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		<=dev-python/coverage-4.0.3[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		<=dev-python/fixtures-1.4.0-r9999[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		<=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		<=dev-python/subunit-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-0.6.0[${PYTHON_USEDEP}]
+		<=dev-python/requests-mock-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		<=dev-python/oslo-sphinx-4.1.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		<=dev-python/testrepository-0.0.20[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		<=dev-python/testtools-1.8.1[${PYTHON_USEDEP}]
+		>=dev-python/testresources-0.2.4[${PYTHON_USEDEP}]
+		<=dev-python/testresources-1.0.0-r9999[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		<=dev-python/testscenarios-0.5[${PYTHON_USEDEP}]
+		>=dev-python/webtest-2.0[${PYTHON_USEDEP}]
+		<=dev-python/webtest-2.0.20[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		<=dev-python/oslotest-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/os-testr-0.1.0[${PYTHON_USEDEP}]
+		<=dev-python/os-testr-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/tempest-lib-0.8.0[${PYTHON_USEDEP}]
+		<=dev-python/tempest-lib-0.11.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-0.7.0[${PYTHON_USEDEP}]
+		<=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		~dev-python/pylint-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/reno-0.1.1[${PYTHON_USEDEP}]
+	)"
+
+RDEPEND="
+	<=dev-python/paste-2.0.2[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0-r1[${PYTHON_USEDEP}]
+	<=dev-python/pastedeploy-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	<=dev-python/routes-2.2[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-0.3.0[${PYTHON_USEDEP}]
+	<=dev-python/debtcollector-1.1.0[${PYTHON_USEDEP}]
+	~dev-python/eventlet-0.17.4[${PYTHON_USEDEP}]
+	>=dev-python/pecan-1.0.0[${PYTHON_USEDEP}]
+	<=dev-python/pecan-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	<=dev-python/greenlet-0.4.9[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	<=dev-python/httplib2-0.9.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.2[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.8.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.9.0[${PYTHON_USEDEP}]
+	<=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.6[${PYTHON_USEDEP}]
+	<=dev-python/jinja-2.8[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-2.0.0[${PYTHON_USEDEP}]
+	!=dev-python/keystonemiddleware-2.4.0[${PYTHON_USEDEP}]
+	<=dev-python/keystonemiddleware-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.12[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	<=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/python-neutronclient-2.6.0[${PYTHON_USEDEP}]
+	<=dev-python/python-neutronclient-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	<=dev-python/retrying-1.3.3[${PYTHON_USEDEP}]
+	>=dev-python/ryu-3.23.2[${PYTHON_USEDEP}]
+	<=dev-python/ryu-3.26[${PYTHON_USEDEP}]
+	compute-only? (
+		>=dev-python/sqlalchemy-0.9.9[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+	)
+	sqlite? (
+		>=dev-python/sqlalchemy-0.9.9[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		dev-python/mysql-python
+		>=dev-python/sqlalchemy-0.9.9[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		dev-python/psycopg:2
+		>=dev-python/sqlalchemy-0.9.9[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+	)
+	>=dev-python/webob-1.2.3[${PYTHON_USEDEP}]
+	<=dev-python/webob-1.5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-1.8.0[${PYTHON_USEDEP}]
+	<=dev-python/python-keystoneclient-2.0.0-r9999[${PYTHON_USEDEP}]
+	>=dev-python/alembic-0.8.0[${PYTHON_USEDEP}]
+	<=dev-python/alembic-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	<=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.5.0[${PYTHON_USEDEP}]
+	<=dev-python/stevedore-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-2.3.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-concurrency-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-2.3.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-config-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-0.2.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-context-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-2.4.1[${PYTHON_USEDEP}]
+	<=dev-python/oslo-db-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-1.5.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-i18n-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-1.8.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-log-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-1.16.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-1.17.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-1.17.1[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.6.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.6.1[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.7.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.8.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.8.1[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-2.9.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-3.1.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-messaging-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-2.8.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-middleware-3.1.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-middleware-3.2.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-middleware-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-0.5.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-policy-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-2.0.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-rootwrap-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.4.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-serialization-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-0.7.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-service-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-utils-2.6.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-utils-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-0.9.0[${PYTHON_USEDEP}]
+	<=dev-python/oslo-versionedobjects-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-2.28.1[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-2.33.0[${PYTHON_USEDEP}]
+	<=dev-python/python-novaclient-2.35.0[${PYTHON_USEDEP}]
+	<=dev-python/pyudev-0.18[${PYTHON_USEDEP}]
+	sys-apps/iproute2
+	net-misc/bridge-utils
+	net-firewall/ipset
+	net-firewall/iptables
+	net-firewall/ebtables
+	openvswitch? ( <=net-misc/openvswitch-2.5.9999 )
+	ipv6? ( net-misc/radvd )
+	dhcp? ( net-dns/dnsmasq[dhcp-tools] )"
+
+PATCHES=(
+)
+
+pkg_setup() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES="VLAN_8021Q IP6_NF_FILTER IP6_NF_IPTABLES IP_NF_TARGET_REJECT \
+	IP_NF_MANGLE IP_NF_TARGET_MASQUERADE NF_NAT_IPV4 NF_CONNTRACK_IPV4 NF_DEFRAG_IPV4 \
+	NF_NAT_IPV4 NF_NAT NF_CONNTRACK IP_NF_FILTER IP_NF_IPTABLES NETFILTER_XTABLES"
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled in kernel"
+		done
+	fi
+	enewgroup neutron
+	enewuser neutron -1 -1 /var/lib/neutron neutron
+}
+
+pkg_config() {
+	fperms 0700 /var/log/neutron
+	fowners neutron:neutron /var/log neutron
+}
+
+src_prepare() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	# it's /bin/ip not /sbin/ip
+	sed -i 's/sbin\/ip\,/bin\/ip\,/g' etc/neutron/rootwrap.d/* || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && make -C doc html
+}
+
+python_test() {
+	# https://bugs.launchpad.net/neutron/+bug/1234857
+	# https://bugs.launchpad.net/swift/+bug/1249727
+	# https://bugs.launchpad.net/neutron/+bug/1251657
+	# Move tests out that attempt net connection, have failures
+	mv $(find . -name test_ovs_tunnel.py) . || die
+	sed -e 's:test_app_using_ipv6_and_ssl:_&:' \
+		-e 's:test_start_random_port_with_ipv6:_&:' \
+		-i neutron/tests/unit/test_wsgi.py || die
+	testr init
+	testr run --parallel || die "failed testsuite under python2.7"
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use server; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-server"
+		newconfd "${FILESDIR}/neutron-server.confd" "neutron-server"
+		dosym /etc/neutron/plugin.ini /etc/neutron/plugins/ml2/ml2_conf.ini
+	fi
+	if use dhcp; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-dhcp-agent"
+		newconfd "${FILESDIR}/neutron-dhcp-agent.confd" "neutron-dhcp-agent"
+	fi
+	if use l3; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-l3-agent"
+		newconfd "${FILESDIR}/neutron-l3-agent.confd" "neutron-l3-agent"
+	fi
+	if use metadata; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-metadata-agent"
+		newconfd "${FILESDIR}/neutron-metadata-agent.confd" "neutron-metadata-agent"
+	fi
+	if use openvswitch; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-openvswitch-agent"
+		newconfd "${FILESDIR}/neutron-openvswitch-agent.confd" "neutron-openvswitch-agent"
+		newinitd "${FILESDIR}/neutron.initd" "neutron-ovs-cleanup"
+		newconfd "${FILESDIR}/neutron-openvswitch-agent.confd" "neutron-ovs-cleanup"
+	fi
+	if use linuxbridge; then
+		newinitd "${FILESDIR}/neutron.initd" "neutron-linuxbridge-agent"
+		newconfd "${FILESDIR}/neutron-linuxbridge-agent.confd.liberty" "neutron-linuxbridge-agent"
+	fi
+	diropts -m 755 -o neutron -g neutron
+	dodir /var/log/neutron /var/lib/neutron
+	keepdir /etc/neutron
+	insinto /etc/neutron
+	insopts -m 0640 -o neutron -g neutron
+
+	doins etc/*
+	# stupid renames
+	rm "${D}etc/neutron/quantum"
+	insinto /etc/neutron
+	doins -r "etc/neutron/plugins"
+	insopts -m 0640 -o root -g root
+	doins "etc/rootwrap.conf"
+	doins -r "etc/neutron/rootwrap.d"
+
+	insopts -m 0644
+	insinto "/usr/lib64/python2.7/site-packages/neutron/db/migration/alembic_migrations/"
+	doins -r "neutron/db/migration/alembic_migrations/versions"
+
+	#add sudoers definitions for user neutron
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/neutron.sudoersd" neutron
+
+	#remove superfluous stuff
+	rm -R "${D}/usr/etc/"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog
+	elog "neutron-server's conf.d file may need updating to include additional ini files"
+	elog "We currently assume the ml2 plugin will be used but do not make assumptions"
+	elog "on if you will use openvswitch or linuxbridge (or something else)"
+	elog
+	elog "Other conf.d files may need updating too, but should be good for the default use case"
+	elog
+}
diff --git a/sys-cluster/neutron/neutron-8.1.0.ebuild b/sys-cluster/neutron/neutron-8.1.1.ebuild
index c15208b51130..c15208b51130 100644
--- a/sys-cluster/neutron/neutron-8.1.0.ebuild
+++ b/sys-cluster/neutron/neutron-8.1.1.ebuild