sys-devel/prelink: drop old

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 0 insertions, 71 deletions

diff --git a/sys-devel/prelink/prelink-20151030.ebuild b/sys-devel/prelink/prelink-20151030.ebuild
deleted file mode 100644
index 1b0b170001a8..000000000000
--- a/sys-devel/prelink/prelink-20151030.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 2002-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-MY_PN="${PN}-cross"
-MY_P="${MY_PN}-${PV}"
-
-inherit autotools flag-o-matic
-
-DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
-HOMEPAGE="https://git.yoctoproject.org/cgit/cgit.cgi/prelink-cross/ https://people.redhat.com/jakub/prelink"
-SRC_URI="https://git.yoctoproject.org/cgit/cgit.cgi/${MY_PN}/snapshot/${MY_P}.tar.bz2
-	doc? ( https://people.redhat.com/jakub/prelink/prelink.pdf )"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm ppc ppc64 x86"
-IUSE="doc selinux"
-
-RDEPEND=">=dev-libs/elfutils-0.100
-	selinux? ( sys-libs/libselinux )
-	!dev-libs/libelf"
-DEPEND="${RDEPEND}
-	sys-libs/binutils-libs"
-
-S=${WORKDIR}/${MY_P}
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-20130503-prelink-conf.patch
-	"${FILESDIR}"/${PN}-20130503-libiberty-md5.patch
-)
-
-# tests were fixed only in development version after 20151030
-RESTRICT=test
-
-src_prepare() {
-	default
-
-	sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
-
-	has_version 'dev-libs/elfutils[threads]' && append-ldflags -pthread
-
-	eautoreconf
-}
-
-src_configure() {
-	econf $(use_enable selinux)
-}
-
-src_install() {
-	default
-
-	use doc && dodoc "${DISTDIR}"/prelink.pdf
-
-	insinto /etc
-	doins doc/prelink.conf
-
-	exeinto /etc/cron.daily
-	newexe "${FILESDIR}"/prelink.cron prelink
-	newconfd "${FILESDIR}"/prelink.confd prelink
-}
-
-pkg_postinst() {
-	if [ -z "${REPLACING_VERSIONS}" ] ; then
-		elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
-		elog "found online at:"
-		elog "    https://wiki.gentoo.org/wiki/Prelink"
-		elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
-	fi
-}