sys-kernel/gentoo-kernel-bin: bump to 5.13.8-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 415dc80e7da4..fc3c12236972 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -61,6 +61,7 @@ DIST gentoo-kernel-5.13.7-1.amd64.xpak 67276613 BLAKE2B 18e0b34b5b6f214d98eec3d1
 DIST gentoo-kernel-5.13.7-1.arm64.xpak 62784203 BLAKE2B fa13585c714e5e0f8a02d23908ef6e4312f04e530869d8827969fc5483bbbe8bd5c9d578a68edf3d7631800b4ef9d4791f44cac5d960d0892e6a401a5503cf62 SHA512 b91ed9f6b9717c1514802a75ef6f2e1d4268dacf95caf404157ad973e7a38d5da34f8ae0d38d2a0f2061e1e1e350815fd0c43c5d322c5affe68989ae160d646e
 DIST gentoo-kernel-5.13.7-1.x86.xpak 58487920 BLAKE2B accf7b6a0f5f57e0759f48ddd6868af0b569571b383b876448424c97c4e7a66a139250752ee3ddb42d314cb8018a45859f9bd3fa3c57074364f4d7a09130a2ef SHA512 456c3aeb610ac6516d46f5ba0944b3cc0d78bbf0d773a7de76abc548f349f9e891ff04ed60420cf51c83588b1b2e162f37034e00416d138daab589b72c67a91b
 DIST gentoo-kernel-5.13.8-1.amd64.xpak 67284810 BLAKE2B 62ab6e2d4849e945ca160a6f0afd8d80e568d58aae569ff3b2e4a98598831fdeedb01ba37ed4b28f5e2d3a00924b783a2891385faa57b5d295a0369c103093f7 SHA512 a0ad7ae5d66f3979851cd99cb5c9021b3f3a55ccb6d98cba4d4a82e750cacc2d0018e2f020e1026f8af93c6c20812b9972d5d8e4ca7a6458f75e30166bb09cec
+DIST gentoo-kernel-5.13.8-1.arm64.xpak 62737848 BLAKE2B cd2cd8ff5c275e053cbaebc4816f97b7ca08bb36aac00c41316c8869c04ee9ebd569caa0dc0f48319f5e523348df5895a106ebfa7df553d48ebb999eba646104 SHA512 fb0b10884699f520914c625e79bcc3f2333c6fe69b74d54608e07e3d2e9c6c7f2f51554c0d84e115e27646d439f92d5ff993f9002bce630d85cbaaa10166adb8
 DIST gentoo-kernel-5.13.8-1.x86.xpak 58496336 BLAKE2B d501a93ae7760c54190f954b40962a6a47a65e7e7e4e9ee4224414c40784bc479178d44a19ba394fb61b4ce6adf0d7c07b6dca0ec8bedfb2b8ffd05940f76b0c SHA512 c4e3a66e8522ceb0bde5e89b434a46e24c9124b580963eff4718b7d380b6c49bc9385ed72490cf877ab9447612bbe29a31155499a64a8df41b32be7ded97c0d9
 DIST gentoo-kernel-5.4.134-1.amd64.xpak 61349154 BLAKE2B c7627b1a8ad85b22450ae1b47a26f9144707f8a2173b01859ea1d876cf4d96e9fcc27be439e6c0239d7494795cc62fa931ecc71be84f9f898ec017a79d82dcf9 SHA512 d4c6613ed069a0ec2dbb5f5bb317abe952309f6ba6fbb163cbf1392478b1756dd129e51665b3b4e9c939395f5cdbc553003d7f0201098f959be9d29233a48cc9
 DIST gentoo-kernel-5.4.134-1.arm64.xpak 56052116 BLAKE2B 6a901fb6a639470145c8b58e435cfe4a380ebd402397ca34eace732936fda8e38a8e92e0f49d747e6f1ae8fb5410960e236ea2cc22dbc7f25ac833275b9b6fea SHA512 216287843b7d1e740afa3c88376e5d5ae99d88882b6669c753fdd341d7f9cd84ee8cbf28fb08f6101b9a9263ce20c6ddeeececf078c7387e571eac53baa52204
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.8-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.8-r1.ebuild
new file mode 100644
index 000000000000..2f16601a52d9
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.8-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}