3 files changed, 186 insertions, 0 deletions
diff --git a/dev-ada/libadalang/libadalang-2017-r2.ebuild b/dev-ada/libadalang/libadalang-2017-r2.ebuild
new file mode 100644
index 000000000000..26e9c93f4feb
--- /dev/null
+++ b/dev-ada/libadalang/libadalang-2017-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+ADA_COMPAT=( gnat_201{6,7} )
+
+inherit ada python-single-r1
+
+DESCRIPTION="high performance semantic engine for the Ada programming language"
+HOMEPAGE="https://libre.adacore.com/"
+SRC_URI="http://mirrors.cdn.adacore.com/art/591c45e2c7a447af2deed042
+	-> ${P}-src.tar.gz"
+
+LICENSE="GPL-3 gcc-runtime-library-exception-3.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="${ADA_DEPS}
+	dev-python/pyyaml
+	dev-ada/gnatcoll[${ADA_USEDEP},projects,shared]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	~dev-ada/langkit-2017"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${PN}-gps-src
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_prepare() {
+	default
+	rm -r ada/testsuite/tests/acats_parse || die
+}
+
+src_configure() {
+	ada/manage.py generate || die
+}
+
+src_compile() {
+	ada/manage.py --verbosity=debug build || die
+}
+
+src_test () {
+	ada/manage.py test | grep FAILED && die
+}
+
+src_install () {
+	ada/manage.py install "${D}"usr
+	python_domodule build/python/libadalang.py
+}
diff --git a/dev-ada/libadalang/libadalang-2018-r2.ebuild b/dev-ada/libadalang/libadalang-2018-r2.ebuild
new file mode 100644
index 000000000000..86894120316e
--- /dev/null
+++ b/dev-ada/libadalang/libadalang-2018-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+ADA_COMPAT=( gnat_201{7,8,9} )
+
+inherit ada python-single-r1
+
+MYP=${PN}-gpl-${PV}-src
+DESCRIPTION="high performance semantic engine for the Ada programming language"
+HOMEPAGE="https://libre.adacore.com/"
+SRC_URI="http://mirrors.cdn.adacore.com/art/5b0cf9adc7a4475263382c18
+	-> ${MYP}.tar.gz"
+
+LICENSE="GPL-3 gcc-runtime-library-exception-3.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs"
+
+RDEPEND="dev-python/pyyaml
+	dev-ada/gnatcoll-bindings[${ADA_USEDEP},iconv,shared=,static-libs=]
+	${ADA_DEPS}
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	~dev-ada/langkit-2018
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${PN}-2017-gentoo.patch
+)
+
+src_configure() {
+	ada/manage.py -v debug generate || die
+}
+
+src_compile() {
+	ada/manage.py \
+		-v \
+		$(use_enable shared) \
+		$(use_enable static-libs static) \
+		build \
+		--build-mode='prod' || die
+}
+
+src_test () {
+	ada/manage.py test | grep FAILED && die
+}
+
+src_install () {
+	ada/manage.py \
+		$(use_enable shared) \
+		$(use_enable static-libs static) \
+		install "${D}"/usr || die
+	python_domodule build/python/libadalang.py
+	rm -r "${D}"/usr/python || die
+}
diff --git a/dev-ada/libadalang/libadalang-2019-r1.ebuild b/dev-ada/libadalang/libadalang-2019-r1.ebuild
new file mode 100644
index 000000000000..23ddcc1668b7
--- /dev/null
+++ b/dev-ada/libadalang/libadalang-2019-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+ADA_COMPAT=( gnat_201{8,9} )
+
+inherit ada python-single-r1
+
+MYP=${P}-20190510-19916-src
+DESCRIPTION="high performance semantic engine for the Ada programming language"
+HOMEPAGE="https://libre.adacore.com/"
+SRC_URI="http://mirrors.cdn.adacore.com/art/5cdf8f3331e87a8f1c967d27
+	-> ${MYP}.tar.gz"
+
+LICENSE="GPL-3 gcc-runtime-library-exception-3.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs"
+
+RDEPEND="dev-python/pyyaml
+	dev-ada/gnatcoll-bindings[${ADA_USEDEP},iconv,shared=,static-libs=]
+	${ADA_DEPS}
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]
+	>=dev-ada/langkit-2019"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_configure() {
+	ada/manage.py -v debug generate || die
+}
+
+src_compile() {
+	libtype=relocatable
+	if use shared; then
+		if use static-libs; then
+			libtype=static,relocatable
+		fi
+	elif use static-libs; then
+		libtype=static
+	fi
+	ada/manage.py \
+		-v \
+		--library-types $libtype \
+		build \
+		--build-mode='prod' || die
+}
+
+src_test () {
+	ada/manage.py test | tee libadalang.testOut;
+	grep -q FAILED libadalang.testOut && die
+}
+
+src_install () {
+	ada/manage.py \
+		-v \
+		--library-types $libtype \
+		install "${D}"/usr || die
+	python_domodule build/python/libadalang
+	rm -r "${D}"/usr/python || die
+}