1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/flufl-lock/flufl-lock-5.1.ebuild b/dev-python/flufl-lock/flufl-lock-5.1.ebuild
new file mode 100644
index 000000000000..57e4a8b7e444
--- /dev/null
+++ b/dev-python/flufl-lock/flufl-lock-5.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="NFS-safe file locking with timeouts for POSIX systems"
+HOMEPAGE="https://gitlab.com/warsaw/flufl.lock"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/atpublic[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' python3_7)"
+BDEPEND="
+	test? ( dev-python/sybil[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov=flufl::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}