blob: 56f3cc81cef2dc4ad70344c05b0c61e3519e338d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
inherit autotools eapi7-ver python-single-r1 systemd
MY_PV_MM=$(ver_cut 1-2)
DESCRIPTION="syslog replacement with advanced filtering features"
HOMEPAGE="https://syslog-ng.com/open-source-log-management"
SRC_URI="https://github.com/balabit/syslog-ng/releases/download/${P}/${P}.tar.gz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="amqp caps dbi geoip geoip2 http ipv6 json libressl mongodb pacct python redis smtp spoof-source systemd tcpd"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
# unit tests require https://github.com/Snaipe/Criterion with additional deps
RESTRICT="test"
RDEPEND="
>=dev-libs/glib-2.10.1:2
>=dev-libs/ivykis-0.42.3
>=dev-libs/libpcre-6.1:=
!dev-libs/eventlog
amqp? ( >=net-libs/rabbitmq-c-0.8.0:= )
caps? ( sys-libs/libcap )
dbi? ( >=dev-db/libdbi-0.9.0 )
geoip? ( >=dev-libs/geoip-1.5.0 )
geoip2? ( dev-libs/libmaxminddb:= )
http? ( net-misc/curl )
json? ( >=dev-libs/json-c-0.9:= )
mongodb? ( >=dev-libs/mongo-c-driver-1.2.0 )
python? ( ${PYTHON_DEPS} )
redis? ( >=dev-libs/hiredis-0.11.0:= )
smtp? ( net-libs/libesmtp )
spoof-source? ( net-libs/libnet:1.1= )
systemd? ( sys-apps/systemd:= )
tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )"
DEPEND="${RDEPEND}
sys-devel/flex
virtual/pkgconfig"
DOCS=( AUTHORS NEWS.md CONTRIBUTING.md contrib/syslog-ng.conf.{HP-UX,RedHat,SunOS,doc}
contrib/syslog2ng "${T}/syslog-ng.conf.gentoo.hardened"
"${T}/syslog-ng.logrotate.hardened" "${FILESDIR}/README.hardened" )
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
local f
use python && python_fix_shebang .
# remove bundled libs
rm -r lib/ivykis modules/afmongodb/mongo-c-driver || die
# drop scl modules requiring json
if use !json; then
sed -i -r '/cim|elasticsearch|ewmm|graylog2|loggly|logmatic/d' scl/Makefile.am || die
fi
# drop scl modules requiring http
if use !http; then
sed -i -r '/telegram/d' scl/Makefile.am || die
fi
# use gentoo default path
if use systemd; then
sed -e 's@/etc/syslog-ng.conf@/etc/syslog-ng/syslog-ng.conf@g;s@/var/run@/run@g' \
-i contrib/systemd/syslog-ng@default || die
fi
for f in syslog-ng.logrotate.hardened.in syslog-ng.logrotate.in; do
sed \
-e "s#@GENTOO_RESTART@#$(usex systemd "systemctl kill -s HUP syslog-ng@default" \
"/etc/init.d/syslog-ng reload")#g" \
"${FILESDIR}/${f}" > "${T}/${f/.in/}" || die
done
for f in syslog-ng.conf.gentoo.fbsd.in \
syslog-ng.conf.gentoo.hardened.in \
syslog-ng.conf.gentoo.in; do
sed -e "s/@SYSLOGNG_VERSION@/${MY_PV_MM}/g" "${FILESDIR}/${f}" > "${T}/${f/.in/}" || die
done
default
eautoreconf
}
src_configure() {
local myconf=(
--disable-docs
--disable-java
--disable-java-modules
--disable-riemann
--enable-manpages
--localstatedir=/var/lib/syslog-ng
--sysconfdir=/etc/syslog-ng
--with-embedded-crypto
--with-ivykis=system
--with-module-dir=/usr/$(get_libdir)/syslog-ng
--with-pidfile-dir=/var/run
--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
$(use_enable amqp)
$(usex amqp --with-librabbitmq-client=system --without-librabbitmq-client)
$(use_enable caps linux-caps)
$(use_enable dbi sql)
$(use_enable geoip)
$(use_enable geoip2)
$(use_enable http)
$(use_enable ipv6)
$(use_enable json)
$(use_enable mongodb)
$(usex mongodb --with-mongoc=system "--without-mongoc --disable-legacy-mongodb-options")
$(use_enable pacct)
$(use_enable python)
$(use_enable redis)
$(use_enable smtp)
$(use_enable spoof-source)
$(use_enable systemd)
$(use_enable tcpd tcp-wrapper)
)
econf "${myconf[@]}"
}
src_install() {
default
# Install default configuration
insinto /etc/default
doins contrib/systemd/syslog-ng@default
insinto /etc/syslog-ng
if use userland_BSD ; then
newins "${T}/syslog-ng.conf.gentoo.fbsd" syslog-ng.conf
else
newins "${T}/syslog-ng.conf.gentoo" syslog-ng.conf
fi
insinto /etc/logrotate.d
newins "${T}/syslog-ng.logrotate" syslog-ng
newinitd "${FILESDIR}/syslog-ng.rc" syslog-ng
newconfd "${FILESDIR}/syslog-ng.confd" syslog-ng
keepdir /etc/syslog-ng/patterndb.d /var/lib/syslog-ng
find "${D}" -name '*.la' -delete || die
use python && python_optimize
}
pkg_postinst() {
# bug #355257
if ! has_version app-admin/logrotate ; then
elog "It is highly recommended that app-admin/logrotate be emerged to"
elog "manage the log files. ${PN} installs a file in /etc/logrotate.d"
elog "for logrotate to use."
fi
if use systemd; then
ewarn "The service file for systemd has changed to support multiple instances."
ewarn "To start the default instance issue:"
ewarn "# systemctl start syslog-ng@default"
fi
}
|
GitWeb