blob: 11dd15e4ff89026c6d87b20e7fbf4faa76c5d6df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
MODULES_OPTIONAL_USE="modules"
inherit autotools linux-mod pam systemd toolchain-funcs user
DESCRIPTION="Opensourced tools for VMware guests"
HOMEPAGE="https://github.com/vmware/open-vm-tools"
MY_P="${P}-4449150"
SRC_URI="https://github.com/vmware/open-vm-tools/files/590760/${MY_P}.tar.gz"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X doc grabbitmqproxy icu pam +pic vgauth xinerama"
RDEPEND="
dev-libs/glib:2
dev-libs/libdnet
sys-apps/ethtool
sys-fs/fuse
>=sys-process/procps-3.3.2
grabbitmqproxy? ( dev-libs/openssl:0 )
icu? ( dev-libs/icu:= )
pam? ( virtual/pam )
vgauth? (
dev-libs/openssl:0
dev-libs/xerces-c
dev-libs/xml-security-c
)
X? (
dev-cpp/gtkmm:3.0
x11-base/xorg-server
x11-drivers/xf86-input-vmmouse
x11-drivers/xf86-video-vmware
x11-libs/gtk+:3
x11-libs/libnotify
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXext
x11-libs/libXi
x11-libs/libXrender
x11-libs/libXrandr
x11-libs/libXtst
xinerama? ( x11-libs/libXinerama )
)
"
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
virtual/pkgconfig
sys-apps/findutils
"
S="${WORKDIR}/${MY_P}/open-vm-tools"
src_prepare() {
eapply -p2 "${FILESDIR}/10.1.0-vgauth.patch"
default
eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-deploypkg
--disable-static
--disable-tests
--with-procps
--with-dnet
$(use_enable doc docs)
$(use_enable grabbitmqproxy)
$(use_enable vgauth)
$(use_enable xinerama multimon)
$(use_with icu)
$(use_with pam)
$(use_with pic)
--without-gtk2
--without-gtkmm
$(use_with X gtk3)
$(use_with X gtkmm3)
$(use_with X x)
$(use_with modules kernel-modules)
--without-root-privileges
--with-kernel-release="${KV_FULL}"
)
econf "${myeconfargs[@]}"
# Bugs 260878, 326761
find . -name Makefile -exec sed -i -e 's/-Werror//g' '{}' + || die "sed out Werror failed"
}
src_compile() {
use modules && set_arch_to_kernel
default
}
src_install() {
default
prune_libtool_files --modules
rm "${ED%/}"/etc/pam.d/vmtoolsd || die
pamd_mimic_system vmtoolsd auth account
newinitd "${FILESDIR}/open-vm-tools.initd" vmware-tools
newconfd "${FILESDIR}/open-vm-tools.confd" vmware-tools
systemd_dounit "${FILESDIR}"/vmtoolsd.service
if use X; then
fperms 4755 /usr/bin/vmware-user-suid-wrapper
dobin scripts/common/vmware-xdg-detect-de
insinto /etc/xdg/autostart
doins "${FILESDIR}"/open-vm-tools.desktop
elog "To be able to use the drag'n'drop feature of VMware for file"
elog "exchange, please add the users to the 'vmware' group."
fi
}
pkg_postinst() {
enewgroup vmware
linux-mod_pkg_postinst
}
|
GitWeb