blob: ef406c8c690c2cfc8f9e60eb38d6dfbb92af3df3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
POSTGRES_COMPAT=( 9.{4..6} {10..12} )
POSTGRES_USEDEP="server"
inherit autotools eutils postgres-multi subversion versionator
MY_PV=$(replace_version_separator 3 '')
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"
ESVN_REPO_URI="http://svn.osgeo.org/postgis/trunk/"
DESCRIPTION="Geographic Objects for PostgreSQL"
HOMEPAGE="http://postgis.net"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="address-standardizer doc gtk static-libs mapbox test topology"
RDEPEND="
${POSTGRES_DEP}
dev-libs/json-c:=
dev-libs/libxml2:2
>=sci-libs/geos-3.5.0
>=sci-libs/proj-4.6.0
>=sci-libs/gdal-1.10.0
address-standardizer? ( dev-libs/libpcre )
gtk? ( x11-libs/gtk+:2 )
mapbox? ( dev-libs/protobuf )
"
DEPEND="${RDEPEND}
doc? (
app-text/docbook-xsl-stylesheets
app-text/docbook-xml-dtd:4.5
dev-libs/libxslt
virtual/imagemagick-tools[png]
)
virtual/pkgconfig
test? ( dev-util/cunit )
"
REQUIRED_USE="test? ( doc )"
# Needs a running psql instance, doesn't work out of the box
RESTRICT="test"
src_prepare() {
source "${S}"/Version.config
export PGIS="${POSTGIS_MAJOR_VERSION}.${POSTGIS_MINOR_VERSION}"
# These modules are built using the same *FLAGS that were used to build
# dev-db/postgresql. The right thing to do is to ignore the current
# *FLAGS settings.
export QA_FLAGS_IGNORED="usr/lib(64)?/(rt)?postgis-${PGIS}\.so"
eapply "${FILESDIR}/${PN}-2.2.0-arflags.patch"
eapply_user
local AT_M4DIR="macros"
eautoreconf
postgres-multi_src_prepare
}
src_configure() {
local myargs=""
use gtk && myargs+=" --with-gui"
use address-standardizer || myargs+=" --without-address-standardizer"
use mapbox || myargs+=" --without-protobuf"
use topology || myargs+=" --without-topology"
postgres-multi_foreach econf ${myargs}
}
src_compile() {
postgres-multi_foreach emake
postgres-multi_foreach emake -C topology
if use doc ; then
postgres-multi_foreach emake comments
postgres-multi_foreach emake cheatsheets
postgres-multi_forbest emake -C doc html
fi
}
src_install() {
postgres-multi_foreach emake DESTDIR="${D}" install
postgres-multi_foreach emake -C topology DESTDIR="${D}" install
postgres-multi_forbest dobin ./utils/postgis_restore.pl
dodoc CREDITS TODO loader/README.* doc/*txt
docinto topology
dodoc topology/{TODO,README}
if use doc ; then
postgres-multi_foreach emake DESTDIR="${D}" comments-install
docinto html
postgres-multi_forbest dodoc doc/html/{postgis.html,style.css}
docinto html/images
postgres-multi_forbest dodoc doc/html/images/*
fi
use static-libs || find "${ED}" -name '*.a' -delete
}
pkg_postinst() {
ebegin "Refreshing PostgreSQL symlinks"
postgresql-config update
eend $?
elog "To finish installing PostGIS, follow the directions detailed at:"
elog "http://postgis.net/docs/manual-dev/postgis_installation.html#create_new_db_extensions"
}
|
GitWeb