blob: b5ba56d21851d086510fd451cbbfada263832941 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit python-single-r1
DESCRIPTION="General purpose formula parser & interpreter"
HOMEPAGE="https://gitlab.com/ixion/ixion"
if [[ ${PV} == *9999 ]]; then
MDDS_SLOT="1/9999"
EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
inherit git-r3 autotools
else
MDDS_SLOT="1/2.0"
SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
fi
LICENSE="MIT"
SLOT="0/0.17" # based on SONAME of libixion.so
IUSE="debug python +threads"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
dev-libs/boost:=
dev-util/mdds:${MDDS_SLOT}
python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
[[ ${PV} == *9999 ]] && eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-static
$(use_enable debug)
$(use_enable debug debug-utils)
$(use_enable debug log-debug)
$(use_enable python)
$(use_enable threads)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -type f -delete || die
}
|
GitWeb
