blob: 476cb552e3686ce60c4c2bdbbf80da23896427fa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
DESCRIPTION="Converting Jupyter Notebooks"
HOMEPAGE="
https://nbconvert.readthedocs.io/
https://github.com/jupyter/nbconvert/
https://pypi.org/project/nbconvert/
"
SRC_URI="
mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
dev-python/bleach[${PYTHON_USEDEP}]
dev-python/defusedxml[${PYTHON_USEDEP}]
>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
dev-python/jupyter_core[${PYTHON_USEDEP}]
dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
>=dev-python/markupsafe-2.0[${PYTHON_USEDEP}]
>=dev-python/mistune-2.0.2[${PYTHON_USEDEP}]
dev-python/nbclient[${PYTHON_USEDEP}]
dev-python/nbformat[${PYTHON_USEDEP}]
>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/tinycss2[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
dev-python/testpath[${PYTHON_USEDEP}]
www-servers/tornado[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pebble[${PYTHON_USEDEP}]
dev-python/ipykernel[${PYTHON_USEDEP}]
dev-python/ipywidgets[${PYTHON_USEDEP}]
>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
PATCHES=(
"${FILESDIR}"/nbconvert-6.5.0-mistune-2.patch
)
src_test() {
mkdir -p "${HOME}/.local" || die
cp -r share "${HOME}/.local/" || die
distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=(
# Missing pyppeteer for now
# TODO: Doesn't skip?
nbconvert/exporters/tests/test_webpdf.py
# Needs pyppeteer too
'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
)
epytest --pyargs nbconvert
}
pkg_postinst() {
if ! has_version app-text/pandoc ; then
einfo "Pandoc is required for converting to formats other than Python,"
einfo "HTML, and Markdown. If you need this functionality, install"
einfo "app-text/pandoc."
fi
}
|
GitWeb