blob: b1104097efa017e1710f27fe6d0d98c84e1f3913 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )
inherit distutils-r1
DESCRIPTION="Collection of various utilities for WSGI applications"
HOMEPAGE="
https://palletsprojects.com/p/werkzeug/
https://pypi.org/project/Werkzeug/
https://github.com/pallets/werkzeug/
"
SRC_URI="
https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="test-rust"
RDEPEND="
>=dev-python/markupsafe-2.1.1[${PYTHON_USEDEP}]
"
# NOTE: remove the loong mask after greenlet gains support for loong
# see https://github.com/python-greenlet/greenlet/pull/257
BDEPEND="
test? (
dev-python/ephemeral-port-reserve[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/pytest-xprocess[${PYTHON_USEDEP}]
dev-python/watchdog[${PYTHON_USEDEP}]
test-rust? (
dev-python/cryptography[${PYTHON_USEDEP}]
)
!hppa? ( !ia64? ( !loong? (
$(python_gen_cond_dep '
dev-python/greenlet[${PYTHON_USEDEP}]
' python3_{8..10})
) ) )
)
"
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=()
if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
"tests/test_serving.py::test_server[https]"
tests/test_serving.py::test_ssl_dev_cert
tests/test_serving.py::test_ssl_object
)
fi
# the default portage tempdir is too long for AF_UNIX sockets
local -x TMPDIR=/tmp
epytest -p no:django -p no:httpbin tests
}
|
GitWeb
