blob: 3b27b0fc1dc9d2f2079115d65b47554315ac4542 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit qt5-build
DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
if [[ ${QT5_BUILD_TYPE} == release ]]; then
KEYWORDS="~amd64 ~arm arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
fi
IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
RDEPEND="
~dev-qt/qtcore-${PV}
~dev-qt/qtgui-${PV}[gles2-only=]
~dev-qt/qtnetwork-${PV}
alsa? ( media-libs/alsa-lib )
gstreamer? (
dev-libs/glib:2
media-libs/gstreamer:1.0
media-libs/gst-plugins-bad:1.0
media-libs/gst-plugins-base:1.0
)
pulseaudio? ( media-sound/pulseaudio[glib] )
qml? (
~dev-qt/qtdeclarative-${PV}
gles2-only? ( ~dev-qt/qtgui-${PV}[egl] )
openal? ( media-libs/openal )
)
widgets? (
~dev-qt/qtopengl-${PV}
~dev-qt/qtwidgets-${PV}[gles2-only=]
)
"
DEPEND="${RDEPEND}
gstreamer? ( x11-base/xorg-proto )
"
PATCHES=(
"${FILESDIR}/${P}-gstreamer-buffering.patch" # QTBUG-83417
)
src_prepare() {
sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
src/multimedia/multimedia.pro || die
qt_use_disable_config openal openal \
src/imports/imports.pro
qt_use_disable_mod qml quick \
src/src.pro \
src/plugins/plugins.pro
qt_use_disable_mod widgets widgets \
src/src.pro \
src/gsttools/gsttools.pro \
src/plugins/gstreamer/common.pri
qt5-build_src_prepare
}
src_configure() {
local myqmakeargs=(
--
$(qt_use alsa)
$(qt_use gstreamer)
$(qt_use pulseaudio)
)
qt5-build_src_configure
}
|
GitWeb
