blob: b99718285db9eb10f5815a7f06c0cc843ea28249 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
USE_RUBY="ruby20 ruby21 ruby22 ruby23"
RUBY_FAKEGEM_TASK_TEST="test:unit"
RUBY_FAKEGEM_TASK_DOC="doc man"
RUBY_FAKEGEM_EXTRADOC="README.markdown"
inherit multilib ruby-fakegem
DESCRIPTION="Implementation of John Gruber's Markdown"
HOMEPAGE="https://github.com/rtomayko/rdiscount"
LICENSE="MIT"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd ~x64-macos"
IUSE=""
all_ruby_prepare() {
# Hanna is broken for us and therefore we don't have it in portage.
sed -i -e 's/hanna/rdoc/' Rakefile || die
# Remove rule that will force a rebuild when running tests.
sed -i -e "/task 'test:unit' => \[:build\]/d" Rakefile || die
# Provide RUBY variable no longer provided by rake.
sed -i -e "1 iRUBY=${RUBY}" Rakefile || die
}
each_ruby_configure() {
${RUBY} -Cext extconf.rb || die
}
each_ruby_compile() {
emake V=1 -Cext || die
cp ext/*$(get_modname) lib/ || die
}
all_ruby_install() {
all_fakegem_install
doman man/rdiscount.1
}
|
GitWeb
