games-arcade/slimevolley/slimevolley-2.4.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit cmake

DESCRIPTION="A simple volleyball game"
HOMEPAGE="http://slime.tuxfamily.org/index.php"
SRC_URI="http://downloads.tuxfamily.org/slime/v242/${PN}_${PV}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

BDEPEND="
	sys-devel/gettext
"
DEPEND="
	media-libs/libsdl[X,sound,video]
	media-libs/sdl-image[png]
	media-libs/sdl-net
	media-libs/sdl-ttf
	virtual/libintl
"
RDEPEND="${DEPEND}"

DOCS=( docs/{README,TODO} )

PATCHES=(
	"${FILESDIR}"/${P}-nodatalocal.patch
	"${FILESDIR}"/${P}-underlink.patch
	"${FILESDIR}"/${P}-gcc10.patch
)

S="${WORKDIR}/${PN}"

src_configure() {
	local mycmakeargs=(
		-DCMAKE_VERBOSE_MAKEFILE=TRUE
		-DDATA_DIR="${EPREFIX}/usr/share/slimevolley"
	)
	cmake_src_configure
}