media-libs/flickcurl/flickcurl-1.26-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

DESCRIPTION="C library for the Flickr API"
HOMEPAGE="https://librdf.org/flickcurl/"
SRC_URI="https://download.dajobe.org/flickcurl/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 GPL-2 Apache-2.0 )"
SLOT="0"
KEYWORDS="amd64 arm64 ~ppc64 x86"
IUSE="raptor"

RDEPEND="
	>=net-misc/curl-7.10.0
	>=dev-libs/libxml2-2.6.8:2
	raptor? ( media-libs/raptor:2 )
"
DEPEND="${RDEPEND}"
BDEPEND="
	dev-build/gtk-doc-am
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}"/${PN}-1.26-c99-configure.patch
	"${FILESDIR}"/${PN}-1.26-c99.patch
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf \
		--disable-gtk-doc \
		$(use_with raptor)
}

src_install() {
	default
	find "${ED}" -name '*.la' -delete || die
}