blob: c953675629aab735e3117b63487c9186d1bd8896 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils flag-o-matic
KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ppc64 sparc x86"
DESCRIPTION="Fast, production-quality, standard-conformant FTP server"
HOMEPAGE="http://www.pureftpd.org/"
SRC_URI="ftp://ftp.pureftpd.org/pub/${PN}/releases/${P}.tar.bz2
http://download.pureftpd.org/pub/${PN}/releases/${P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
IUSE="anondel anonperm anonren anonres caps charconv implicittls ldap libressl mysql noiplog pam paranoidmsg postgres resolveids selinux ssl sysquota vchroot xinetd"
REQUIRED_USE="implicittls? ( ssl )"
DEPEND="caps? ( sys-libs/libcap )
charconv? ( virtual/libiconv )
ldap? ( >=net-nds/openldap-2.0.25 )
mysql? ( virtual/mysql )
pam? ( virtual/pam )
postgres? ( dev-db/postgresql:= )
ssl? (
!libressl? ( >=dev-libs/openssl-0.9.6g:0=[-bindist] )
libressl? ( dev-libs/libressl:= )
)
sysquota? ( sys-fs/quota[-rpc] )
xinetd? ( virtual/inetd )"
RDEPEND="${DEPEND}
dev-libs/libsodium:=
net-ftp/ftpbase
selinux? ( sec-policy/selinux-ftp )"
PATCHES=(
"${FILESDIR}"/${PN}-1.0.28-pam.patch
)
src_configure() {
# adjust max user length to something more appropriate
# for virtual hosts. See bug #62472 for details.
sed -e "s:# define MAX_USER_LENGTH 32U:# define MAX_USER_LENGTH 127U:" \
-i "${S}/src/ftpd.h" || die "sed failed"
# Those features are only configurable like this, see bug #179375.
use anondel && append-cppflags -DANON_CAN_DELETE
use anonperm && append-cppflags -DANON_CAN_CHANGE_PERMS
use anonren && append-cppflags -DANON_CAN_RENAME
use anonres && append-cppflags -DANON_CAN_RESUME
use resolveids && append-cppflags -DALWAYS_RESOLVE_IDS
# Do not auto-use SSP -- let the user select this.
export ax_cv_check_cflags___fstack_protector_all=no
local myeconfargs=(
--enable-largefile
--with-altlog
--with-cookie
--with-diraliases
--with-extauth
--with-ftpwho
--with-language=${PUREFTPD_LANG:=english}
--with-peruserlimits
--with-privsep
--with-puredb
--with-quotas
--with-ratios
--with-throttling
--with-uploadscript
--with-virtualhosts
$(use_with charconv rfc2640)
$(use_with ldap)
$(use_with mysql)
$(use_with pam)
$(use_with paranoidmsg)
$(use_with postgres pgsql)
$(use_with ssl tls)
$(use_with implicittls)
$(use_with vchroot virtualchroot)
$(use_with sysquota sysquotas)
$(usex caps '' '--without-capabilities')
$(usex noiplog '--without-iplogging' '')
$(usex xinetd '' '--without-inetd')
)
econf "${myeconfargs[@]}"
}
src_install() {
local DOCS=( AUTHORS CONTACT ChangeLog FAQ HISTORY INSTALL README* NEWS )
default
newinitd "${FILESDIR}/pure-ftpd.rc11" ${PN}
newconfd "${FILESDIR}/pure-ftpd.conf_d-3" ${PN}
if use implicittls ; then
sed -i '/^SERVER/s@21@990@' "${ED}"/etc/conf.d/${PN} \
|| die "Adjusting default server port for implicittls usage failed!"
fi
keepdir /var/lib/run/${PN}
if use xinetd ; then
insinto /etc/xinetd.d
newins "${FILESDIR}/pure-ftpd.xinetd" ${PN}
fi
if use ldap ; then
insinto /etc/openldap/schema
doins pureftpd.schema
insinto /etc/openldap
insopts -m 0600
doins pureftpd-ldap.conf
fi
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
# This is a new installation
elog
elog "Before starting Pure-FTPd, you have to edit the /etc/conf.d/pure-ftpd file!"
elog
ewarn "It's *really* important to read the README provided with Pure-FTPd!"
ewarn "Check out http://download.pureftpd.org/pub/pure-ftpd/doc/README for general info"
ewarn "and http://download.pureftpd.org/pub/pure-ftpd/doc/README.TLS for SSL/TLS info."
ewarn
if use charconv ; then
ewarn "Charset conversion is an *experimental* feature!"
ewarn "Remember to set a valid charset for your filesystem in the configuration!"
fi
fi
}
|
GitWeb