blob: 5112f7ee494fb02c17748aad756ce8fcb44991a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 2019-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit systemd toolchain-funcs
DESCRIPTION="SSH tarpit that slowly sends and endless banner"
HOMEPAGE="https://github.com/skeeto/endlessh"
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/skeeto/${PN}.git"
else
SRC_URI="https://github.com/skeeto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="amd64 ~arm ~arm64 ppc64 x86"
fi
LICENSE="Unlicense"
SLOT="0"
PATCHES=(
"${FILESDIR}"/${PN}-1.1-syslog-help.patch
)
src_prepare() {
default
tc-export CC
sed -i \
-e 's/^CC/CC?/' \
-e 's/^CFLAGS =/CFLAGS +=/' \
-e 's/ -Os//' \
-e 's/^LDFLAGS/LDFLAGS?/' \
-e 's/^PREFIX/PREFIX?/' \
Makefile || die
sed -i -e "/^ExecStart=/ s:=/usr/local:=${EPREFIX}/usr:" \
-e /InaccessiblePaths/d util/endlessh.service || die
}
src_install() {
emake DESTDIR="${D}" PREFIX=/usr install
einstalldocs
newinitd "${FILESDIR}"/endlessh.initd endlessh
newconfd "${FILESDIR}"/endlessh.confd endlessh
systemd_dounit util/endlessh.service
insinto /usr/share/${PN}
doins util/{pivot.py,schema.sql}
}
pkg_postinst() {
elog "Log parsing script installed to ${EPREFIX}/usr/share/${PN}"
elog "Install dev-python/pyrfc3339 if you are going to use it"
}
|
GitWeb
