blob: 45c90ec179d619a8a81f6fa74f7305f4bed03558 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 )
inherit python-single-r1 user flag-o-matic
MY_P="${PN}2-${PV}"
DESCRIPTION="Virtual distributed ethernet emulator for emulators like qemu, bochs, and uml"
SRC_URI="mirror://sourceforge/vde/${MY_P}.tar.bz2"
HOMEPAGE="http://vde.sourceforge.net/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~ppc ~ppc64 x86"
IUSE="pcap python selinux ssl libressl static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
COMMON_DEPS="pcap? ( net-libs/libpcap )
python? ( ${PYTHON_DEPS} )
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)"
DEPEND="${COMMON_DEPS}"
RDEPEND="${COMMON_DEPS}
selinux? ( sec-policy/selinux-vde )"
S="${WORKDIR}/${MY_P}"
PATCHES=( "${FILESDIR}/${P}-format-security.patch" )
pkg_setup() {
# default group already used in kqemu
enewgroup qemu
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
has_version ">=dev-libs/openssl-1.1.0" && eapply "${FILESDIR}/${P}-openssl-1.1.patch"
}
src_configure() {
filter-flags -O0 -Os
econf \
$(use_enable pcap) \
$(use_enable python) \
$(use_enable ssl cryptcab) \
$(use_enable static-libs static)
}
src_compile() {
emake -j1
}
src_install() {
default
find "${D}" -name '*.la' -type f -delete || die
newinitd "${FILESDIR}"/vde.init-r1 vde
newconfd "${FILESDIR}"/vde.conf-r1 vde
}
pkg_postinst() {
einfo "To start vde automatically add it to the default runlevel:"
einfo "# rc-update add vde default"
einfo "You need to setup tap0 in /etc/conf.d/net"
einfo "To use it as an user be sure to set a group in /etc/conf.d/vde"
}
|
GitWeb
