blob: 12a3e2149381fd5f1bf8b1dad56c8374cb907da4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools flag-o-matic usr-ldscript
DESCRIPTION="Reiserfs Utilities"
HOMEPAGE="https://www.kernel.org/pub/linux/utils/fs/reiserfs/"
SRC_URI="https://www.kernel.org/pub/linux/utils/fs/reiserfs/${P}.tar.xz
https://www.kernel.org/pub/linux/kernel/people/jeffm/${PN}/v${PV}/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv -sparc x86 ~amd64-linux ~x86-linux"
IUSE="static-libs"
PATCHES=(
"${FILESDIR}/${PN}-3.6.25-no_acl.patch"
"${FILESDIR}/${PN}-3.6.27-loff_t.patch"
)
# Needed for libuuid
RDEPEND="sys-apps/util-linux"
DEPEND="${RDEPEND}"
src_prepare() {
default
eautoreconf
}
src_configure() {
append-flags -std=gnu89 #427300
local myeconfargs=(
--bindir="${EPREFIX}/bin"
--libdir="${EPREFIX}/$(get_libdir)"
--sbindir="${EPREFIX}/sbin"
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
dodir /usr/$(get_libdir)
mv "${ED}"/$(get_libdir)/pkgconfig "${ED}"/usr/$(get_libdir) || die
if use static-libs ; then
mv "${ED}"/$(get_libdir)/*a "${ED}"/usr/$(get_libdir) || die
gen_usr_ldscript libreiserfscore.so
else
find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
fi
}
|
GitWeb
