x11-misc/openbox-menu/openbox-menu-0.5.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="Another dynamic menu generator for Openbox"
HOMEPAGE="http://mimasgpc.free.fr/openbox-menu_en.html"
SRC_URI="https://bitbucket.org/fabriceT/${PN}/downloads/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="+icons svg"
REQUIRED_USE="svg? ( icons )"

CDEPEND="
	dev-libs/glib:2
	lxde-base/menu-cache
	x11-libs/gtk+:2
"
RDEPEND="
	${CDEPEND}
	icons? ( x11-wm/openbox[imlib,svg?] )
	!icons? ( x11-wm/openbox )
"
DEPEND="
	${CDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.5.0-build.patch
	epatch_user
	tc-export CC PKG_CONFIG
}

src_compile() {
	emake \
		$(usex icons 'ICONS=1' 'ICONS=0') \
		$(usex svg 'SVG_ICONS=1' 'SVG_ICONS=0')
}