Add sys-apps/openrc-0.19.1

2 files changed, 382 insertions, 0 deletions

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 716df2ac..703a0f79 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -38,6 +38,7 @@ DIST openrc-0.13.9.tar.bz2 151021 SHA256 2ce932dfcbaf0ddf5fd79eb9ff75efe3bc9ce5a
 DIST openrc-0.16.4.tar.bz2 158599 SHA256 6771257e208da2e4d20b4ac2e3e7f065eb8873566644ff385e9dbd6bc5221d21 SHA512 8ade50cdb8c2e05e00e917f848e96bfee54bb4ac77bf50af8c5ab66e2e01f8a5c2621123087945feaa9b15ad84a5936e23cc489a2bb7127c2b118a5a0695ee6e WHIRLPOOL 706d7b1101927ff89afb01ad766f491db94ff04f574bc7b69349b6ab0334ed5d2cd5ee2d8041cf5a0ba00f5a6a3596502835fa132c668533772a42737f0e2412
 DIST openrc-0.17.tar.bz2 160533 SHA256 45818d9ef4659e8dd924a1468a091255c305daee5417f94d9515f0e125298b30 SHA512 6e69b036d113f066b0dd0bfe55e019328e0e77cff6c93f0a3e55751aa0a72411aa3b1efe8b4327e156a9612e4155863b0a81c9eda043c12904bb36e861b71399 WHIRLPOOL de45daf6f4aebe632ea9fcb46408e63f0aed6c9b9129fb5510f348f20cf1c62aa42e7dce47a7f19a441696596fa57494642e7334a42c415fdbc865cb80a18eff
 DIST openrc-0.18.4.tar.bz2 157237 SHA256 2c8bf1c6f52fcf4c1f6945a2836ba2551a7d93015aa63ba5a2e1d2851c2942e4 SHA512 13f5dbc1292ce94c2e42a35e582bbba12e4bba943640952ea4cecc7ff5c60175d362055a4f5e213f218236ab4a040a5dff01a47c8bc007237554744d8a89a48a WHIRLPOOL f1f44effad80863276339af5bce1b3a9068d9c5ae7f7c3b571fb883b376c9083c207980c6d05170b0a18c0902ad1e2d76a1bafb0f11721b0522308e2cb7c67b4
+DIST openrc-0.19.1.tar.bz2 159598 SHA256 5628c04b12e2f51f25e59c303bdccbf545ba0db25484adcca48e70d0712ce0e6 SHA512 303db4475fd02aa3aa161dbd8794a45c2633b9fe96aaab67b81014fa3915bed1aa51cff57128f4413cf9f2329ce1f2012e460e089c39f01ac6eb061a95844329 WHIRLPOOL a4e8720579b8983cb3c2c9b4dd983c1b7bf45e053aa0c9545f31e36c22e44d06e55198d4143dc0a6bca3b7d00b151b43d1da439b2479044344ca12f3151711f1
 EBUILD openrc-0.11.5.ebuild 16502 SHA256 caf32e93a383ab1ac1766999f85292029c194380ff92007f05c08514401d2740 SHA512 54fc14f6e2a6c11d0446f12f75d78f74cc6c37b863eaa68d7f898770c5b6b96807ce6de190f86b0db472042c3a94ae2976049c374ca884bda5d1bc5732751700 WHIRLPOOL 69b03be1a1da0d571b27d915324802295325a5b7c41e4ae294abbad40ee0deaac89e64d727914a45c8f9579c1453dd8b19f78d3230d8fe9947b86d2ca86f1043
 EBUILD openrc-0.11.6.ebuild 16537 SHA256 408e9a98ffb81c84e287acdc82ac1839861957ecda23d7cb575c889ce68a227d SHA512 fc6089241dbe5139fa19069864c5ca0e3cbc5b289ea7678d676edfed4058a3acf5c1cad40188a954156c65f8332b7ba5726549cb5061a4ef5fbbed1afd7beb7f WHIRLPOOL 8ad01c29ef9be7aab107712e50ddae5f8879da64c875d2a60b3502bbd3515a872a9d2861584a2bf9974cd0b06a45b85f9d605b9835705494b6ce818f897bfb27
 EBUILD openrc-0.11.8.ebuild 17228 SHA256 16dc63fd49833ccceabdf6f2fc8b34d298bb662e058f76d46683c40ae4028ede SHA512 c5ad283417c1a8eb49e23ff6841e6322f5acb46769c314b320b2ab843f3436edbe2ffd5a532b6785564d20a475da11ab3e8e770ba4af6b6cd5f219b798b896ce WHIRLPOOL e67e717a3b3c2b170a22b0c35b2609f3409e8e2909f1031d7f27dae35657f5ed1385374689bf91ad888f5b2a98730910e6ff8230a8bbd3e4c51faeb469c23bb5
@@ -50,3 +51,4 @@ EBUILD openrc-0.13.9.ebuild 11602 SHA256 518d540842151993cd952e2fce2f40c2b735520
 EBUILD openrc-0.16.4.ebuild 11800 SHA256 18c564e7faf5d4674c8e54d9c7ca4d5f8bf56568b0b62fd4be9f0c243a37e5ce SHA512 f4f2a19b7abc67dccce6b06e196bcdcd48fc7d0d3e7a3f3c3bc19265b6bdfd27196a67c77f07036bb6e9330dc706a5ed98415e9259d45a90ffc3347be2f68b1a WHIRLPOOL 6d3cf645da55e0afe947a4004e26acfc1608600c3bcc32fb88436e5a6d539f490dc715762371547d54572e17eea56ec5091dad7960d595e526f376e51ea17df5
 EBUILD openrc-0.17.ebuild 12035 SHA256 f3a876629ab6185a21ad20cb5eb1f22eb58fb3f4cafc043420c0821440592671 SHA512 4d2bc88bce2c1245650a6bbc17eba9e8c078dd4b1ba657f31df38efd2f88bf45a4dd549206abcd4445adae71756c101a85b7bc4d7c8932dffe415c4beb722732 WHIRLPOOL 9b30cf72490ba5b9d5350e6a53f657aed8cf895febb7c5488df8a46772e15da0462d035c3d9802147af86e03dd3aaf813c5d0875883fcc53065c71b6b5ba4d64
 EBUILD openrc-0.18.4.ebuild 12500 SHA256 dc71252c56bbcc7a1280ad4c139f31551c7a144023fc71f3e8d00d833e45af28 SHA512 cf576e271c3b9971cc794cdd7684bfd2d394cc5796a2e39fd966239c7a5c2e6e54b40fd6f5dff7da8294276c108b3b9c836ec4a121c74554454d018963dbc767 WHIRLPOOL 3137f1635ef0fc920f0f9aa99c629fbd00cea14bbbcff0832b7924aca956ad5f4a791a61118577c280d0458dd35bda25e8cf952183a55f476bdcd8fb0c26ed79
+EBUILD openrc-0.19.1.ebuild 12498 SHA256 c1cb3dbdfe4e4b4c195d9496eb1a4bf4dc7d34c81f14524cc9a5b359507c611a SHA512 686a6744d9eeb56788a0108ad53292877f8deee5a66a5bcef9a2a8aa9bd9264ff0d03707da2a129fea59b55c86acaf7baa60cff6fa6735509223c2c116b28f85 WHIRLPOOL 193fc17c2803877bd03b9e6f71466d630de0073e6045230c37a37b95c4b5768dac3c59a63df7cd29db71d5ebe3f9b8ace8780cc4986e5c8e3328275a5864421c
diff --git a/sys-apps/openrc/openrc-0.19.1.ebuild b/sys-apps/openrc/openrc-0.19.1.ebuild
new file mode 100644
index 00000000..c1a0463b
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.19.1.ebuild
@@ -0,0 +1,380 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id: 29efb42afcae55497484d04c3cd293b66a09f8a2 $
+
+EAPI=5
+
+inherit eutils flag-o-matic multilib pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~williamh/dist/${P}.tar.bz2"
+	KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit debug elibc_glibc ncurses pam newnet prefix +netifrc selinux static-libs
+	+tmpfs tools unicode -vanilla +varrun kernel_linux kernel_FreeBSD"
+
+COMMON_DEPEND="kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-ubin-9.0_rc sys-process/fuser-bsd ) )
+	elibc_glibc? ( >=sys-libs/glibc-2.5 )
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? (
+		sys-auth/pambase
+		virtual/pam
+	)
+	tools? ( dev-lang/perl )
+	audit? ( sys-process/audit )
+	kernel_linux? (
+		sys-process/psmisc
+		!<sys-process/procps-3.3.9-r2
+	)
+	selinux? (
+		sys-apps/policycoreutils
+		sys-libs/libselinux
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	!prefix? (
+		kernel_linux? ( || ( >=sys-apps/sysvinit-2.86-r6 sys-process/runit ) )
+		kernel_FreeBSD? ( sys-freebsd/freebsd-sbin )
+	)
+	selinux? (
+		sec-policy/selinux-base-policy
+		sec-policy/selinux-openrc
+	)
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_prepare() {
+	sed -i 's:0444:0644:' mk/sys.mk || die
+
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/gitver.mk || die
+	fi
+
+	if use vanilla; then
+		if use varrun || use tmpfs; then
+			ewarn "Overlay tmpfs and /var/run patches will not be applied when building a stock OpenRC"
+		fi
+	else
+		if use varrun ; then
+			epatch "${FILESDIR}/openrc-0.16.4-norun.patch" || die "epatch failed"
+		else
+			epatch "${FILESDIR}/openrc-0.12.4-bootmisc.in.patch" || die "bootmisc.in epatch failed"
+		fi
+		if use tmpfs; then
+			epatch "${FILESDIR}/openrc-0.12.4-tmpfs.patch" || die "tmpfs epatch failed"
+		fi
+		epatch "${FILESDIR}/openrc-0.16.4-init.patch" || die "init epatch failed"
+		epatch "${FILESDIR}/openrc-0.18.4-devfs.patch" || die "devfs epatch failed"
+	fi
+	epatch "${FILESDIR}/openrc-0.16.4-cgroup-race.patch" || die "cgroup epatch failed"
+
+	# Allow user patches to be applied without modifying the ebuild
+	epatch_user
+}
+
+src_compile() {
+	unset LIBDIR #266688
+
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBNAME=$(get_libdir)
+		LIBEXECDIR=${EPREFIX}/$(get_libdir)/rc
+		MKNET=$(usex newnet)
+		MKSELINUX=$(usex selinux)
+		MKAUDIT=$(usex audit)
+		MKPAM=$(usev pam)
+		MKSTATICLIBS=$(usex static-libs)
+		MKTOOLS=$(usex tools)"
+
+	local brand="Unknown"
+	if use kernel_linux ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=Linux"
+		brand="Linux"
+	elif use kernel_FreeBSD ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=FreeBSD"
+		brand="FreeBSD"
+	fi
+	export BRANDING="Gentoo ${brand}"
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+	export DEBUG=$(usev debug)
+	export MKTERMCAP=$(usev ncurses)
+
+	tc-export CC AR RANLIB
+	emake ${MAKE_ARGS}
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+
+	# move the shared libs back to /usr so ldscript can install
+	# more of a minimal set of files
+	# disabled for now due to #270646
+	#mv "${ED}"/$(get_libdir)/lib{einfo,rc}* "${ED}"/usr/$(get_libdir)/ || die
+	#gen_usr_ldscript -a einfo rc
+	gen_usr_ldscript libeinfo.so
+	gen_usr_ldscript librc.so
+
+	if use varrun || ! use kernel_linux; then
+		keepdir "${EROOT}"$(get_libdir)/rc/init.d
+	fi
+	keepdir "${EROOT}"$(get_libdir)/rc/tmp
+
+	if ! use vanilla; then
+		# Install updated /etc/init.d/root script, allowing /etc/fstab options to
+		# determine mount options for the root filesystem
+		newinitd "${FILESDIR}"/root-r1.initd root
+		# Install updated /etc/init.d/localmount script, to run:
+		#  `btrfs devices scan`
+		# ... before attempting to mount local btrfs filesystems
+		newinitd "${FILESDIR}"/localmount-r2.initd localmount
+
+		# Restore now-integrated script
+		exeinto "${EROOT}"$(get_libdir)/rc/sh
+		newexe "${FILESDIR}"/${PN}-0.13.7-init-common-post.sh init-common-post.sh
+	fi
+
+	# Backup our default runlevels
+	dodir /usr/share/"${PN}"
+	cp -PR "${ED}"/etc/runlevels "${ED}"/usr/share/${PN} || die
+	rm -rf "${ED}"/etc/runlevels
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/usr/share/openrc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	# install the gentoo pam.d file
+	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+
+	# install documentation
+	dodoc ChangeLog *.md
+	if use newnet; then
+		dodoc README.newnet
+	fi
+}
+
+add_boot_init() {
+	local initd=$1
+	local runlevel=${2:-boot}
+	# if the initscript is not going to be installed and is not
+	# currently installed, return
+	[[ -e "${ED}"/etc/init.d/${initd} || -e "${EROOT}"etc/init.d/${initd} ]] \
+		|| return
+	[[ -e "${EROOT}"etc/runlevels/${runlevel}/${initd} ]] && return
+
+	# if runlevels dont exist just yet, then create it but still flag
+	# to pkg_postinst that it needs real setup #277323
+	if [[ ! -d "${EROOT}"etc/runlevels/${runlevel} ]] ; then
+		mkdir -p "${EROOT}"etc/runlevels/${runlevel}
+		touch "${EROOT}"etc/runlevels/.add_boot_init.created
+	fi
+
+	elog "Auto-adding '${initd}' service to your ${runlevel} runlevel"
+	ln -snf "${EROOT}"etc/init.d/${initd} "${EROOT}"etc/runlevels/${runlevel}/${initd}
+}
+add_boot_init_mit_config() {
+	local config=$1 initd=$2
+	if [[ -e ${EROOT}${config} ]] ; then
+		if [[ -n $(sed -e 's:#.*::' -e '/^[[:space:]]*$/d' "${EROOT}"${config}) ]] ; then
+			add_boot_init ${initd}
+		fi
+	fi
+}
+
+pkg_preinst() {
+	local f LIBDIR=$(get_libdir)
+
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell "${EROOT}"sbin/sulogin "#" test -e "${EROOT}"sbin/sulogin
+
+	# termencoding was added in 0.2.1 and needed in boot
+	has_version ">=sys-apps/openrc-0.2.1" || add_boot_init termencoding
+
+	# swapfiles was added in 0.9.9 and needed in boot (february 2012)
+	has_version ">=sys-apps/openrc-0.9.9" || add_boot_init swapfiles
+
+	if ! has_version ">=sys-apps/openrc-0.11"; then
+		add_boot_init sysfs sysinit
+	fi
+
+	if ! has_version ">=sys-apps/openrc-0.11.3" ; then
+		migrate_udev_mount_script
+		add_boot_init tmpfiles.setup boot
+	fi
+
+	# these were added in 0.12.
+	if ! has_version ">=sys-apps/openrc-0.12"; then
+		add_boot_init loopback
+		add_boot_init tmpfiles.dev sysinit
+
+		# ensure existing /etc/conf.d/net is not removed
+		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
+		# this needs to stay in openrc ebuilds for a long time. :(
+		# Added in 0.12.
+		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
+			einfo "Modifying conf.d/net to keep it from being removed"
+			cat <<-EOF >>"${EROOT}"etc/conf.d/net
+
+# The network scripts are now part of net-misc/netifrc
+# In order to avoid sys-apps/${P} from removing this file, this comment was
+# added; you can safely remove this comment.  Please see
+# /usr/share/doc/netifrc*/README* for more information.
+EOF
+		fi
+	fi
+	has_version ">=sys-apps/openrc-0.14" || add_boot_init binfmt
+
+	if ! has_version ">=sys-apps/openrc-0.18.3"; then
+		add_boot_init mtab
+		if [[ -f "${EROOT}"etc/mtab ]] && [[ ! -L "${EROOT}"etc/mtab ]]; then
+			ewarn "${EROOT}etc/mtab will be replaced with a"
+			ewarn "symbolic link to /proc/self/mounts on the next"
+			ewarn "reboot."
+			ewarn "Change the setting in ${EROOT}etc/conf.d/mtab"
+			ewarn "if you do not want this to happen."
+		fi
+	fi
+}
+
+# >=OpenRC-0.11.3 requires udev-mount to be in the sysinit runlevel with udev.
+migrate_udev_mount_script() {
+	if [ -e "${EROOT}"etc/runlevels/sysinit/udev -a \
+		! -e "${EROOT}"etc/runlevels/sysinit/udev-mount ]; then
+		add_boot_init udev-mount sysinit
+	fi
+	return 0
+}
+
+pkg_postinst() {
+	local LIBDIR=$(get_libdir)
+
+	# Make our runlevels if they don't exist
+	if [[ ! -e "${EROOT}"etc/runlevels ]] || [[ -e "${EROOT}"etc/runlevels/.add_boot_init.created ]] ; then
+		einfo "Copying across default runlevels"
+		cp -RPp "${EROOT}"usr/share/${PN}/runlevels "${EROOT}"etc
+		rm -f "${EROOT}"etc/runlevels/.add_boot_init.created
+	else
+		if [[ ! -e "${EROOT}"etc/runlevels/sysinit/devfs ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/sysinit
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/sysinit/* \
+				"${EROOT}"etc/runlevels/sysinit
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/shutdown/mount-ro ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/shutdown
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/shutdown/* \
+				"${EROOT}"etc/runlevels/shutdown
+		fi
+	fi
+
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Handle the conf.d/local.{start,stop} -> local.d transition
+	if path_exists -o "${EROOT}"etc/conf.d/local.{start,stop} ; then
+		elog "Moving your ${EROOT}etc/conf.d/local.{start,stop}"
+		elog "files to ${EROOT}etc/local.d"
+		mv "${EROOT}"etc/conf.d/local.start "${EROOT}"etc/local.d/baselayout1.start
+		mv "${EROOT}"etc/conf.d/local.stop "${EROOT}"etc/local.d/baselayout1.stop
+		chmod +x "${EROOT}"etc/local.d/*{start,stop}
+	fi
+
+	if ! use varrun && use kernel_linux && [[ "${EROOT}" = "/" ]]; then
+		if ! "${EROOT}"$(get_libdir)/rc/sh/migrate-to-run.sh; then
+			ewarn "The dependency data could not be migrated to /run/openrc."
+			ewarn "This means you need to reboot your system."
+		fi
+	fi
+
+	# update the dependency tree after touching all files #224171
+	[[ "${EROOT}" = "/" ]] && "${EROOT}/${LIBDIR}"/rc/bin/rc-depend -u
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRC without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
+		ewarn "net-misc/NetworkManager, or net-misc/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+
+	ewarn "In this version of OpenRC, the loopback interface no longer"
+	ewarn "satisfies the net virtual."
+	ewarn "If you have services now which do not start because of this,"
+	ewarn "They can be fixed by adding rc_need=\"!net\""
+	ewarn "to the ${EROOT}etc/conf.d/<servicename> file."
+	ewarn "You should also file a bug against the service asking that"
+	ewarn "need net be dropped from the dependencies."
+	ewarn "The bug you file should block the following tracker:"
+	ewarn "https://bugs.gentoo.org/show_bug.cgi?id=439092"
+	ewarn
+
+	# Updated for 0.13.2.
+	ewarn "Bug https://bugs.gentoo.org/show_bug.cgi?id=427996 was not"
+	ewarn "fixed correctly in earlier versions of OpenRC."
+	ewarn "The correct fix is implemented in this version, but that"
+	ewarn "means netmount needs to be added to the default runlevel if"
+	ewarn "you are using nfs file systems."
+	ewarn
+
+	elog "You should now update all files in /etc, using etc-update"
+	elog "or equivalent before restarting any services or this host."
+}