Version bump; new dependency, fixed tests.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-ruby/thor/thor-0.15.2.ebuild b/dev-ruby/thor/thor-0.15.2.ebuild
new file mode 100644
index 000000000000..60a8ccc4a636
--- /dev/null
+++ b/dev-ruby/thor/thor-0.15.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/thor-0.15.2.ebuild,v 1.1 2012/06/07 21:57:39 flameeyes Exp $
+
+EAPI=4
+USE_RUBY="ruby18 ree18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.rdoc README.md"
+RUBY_FAKEGEM_BINWRAP="thor"
+
+RUBY_S="wycats-${PN}-*"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A scripting framework that replaces rake and sake"
+HOMEPAGE="http://github.com/wycats/thor"
+
+SRC_URI="http://github.com/wycats/${PN}/tarball/v${PV} -> ${PN}-git-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/fakeweb
+		dev-ruby/rspec:2
+		dev-ruby/childlabor
+	)
+	doc? (
+		dev-ruby/rdoc
+	)"
+
+all_ruby_prepare() {
+	# Remove rspec default options (as we might not have the last
+	# rspec).
+	rm .rspec || die
+
+	# Remove Bundler
+	rm Gemfile || die
+	sed -i -e '/[Bb]undler/d' Thorfile || die
+
+	# Remove mandatory coverage collection using simplecov which is not
+	# packaged.
+	sed -i -e '/require .simplecov/, /^end/ d' spec/spec_helper.rb || die
+}
+
+all_ruby_compile() {
+	if use doc; then
+		ruby -Ilib bin/thor rdoc || die "RDoc generation failed"
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} -S rspec spec || die "Tests for ${RUBY} failed"
+}